;;;Place woodline linear symbol as an anonymous block.
;;;
;;;              
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 3-20-96
;;;>		   EDITED: 04-08-1997
;;;
(DEFUN C:NTREE ( / undrw osmod pt0 pt1 pt2 pt4 fenl count cispc sang eang)
(setq osmod (getvar"osmode"))
(setvar "osmode" 0)
  (setq dimsc (getvar"dimscale"))
  (if (eq modf "XIST")
    (setq pt1 (upoint 0 "" "Existing Woods Line beginning point" nil nil))
    (setq pt1 (upoint 0 "" "Proposed Woods Line beginning point" nil nil))
  );if
  (entmake
    (list
      (cons 0 "BLOCK")
      (cons 70 1)
      (cons 2 "*U")
      (cons 10 (list 0 0 0))
    )
  )
  (while
    (setq pt2 (upoint 0 "" "Next Woods Line point" nil pt1))
    (setq fenl (distance pt1 pt2)
          count (1+(fix(/ fenl (* dimsc 0.25))))
          cispc (/ fenl count)
          sang (angle pt1 pt2)
          eang (angle pt2 pt1)
          undrw (if undrw(append undrw (list 0 pt1 pt2))(list 0 pt1 pt2))
    );setq
    (grdraw pt1 pt2 7)
    (while
      (> count 0)
    (setq pt0 (polar pt1 sang (/ cispc 2))
          pt4 (polar pt1 sang cispc)
    );setq
    (entmake
      (list
        (cons 0 "ARC")
        (cons 8 "0")
        (cons 10 pt0)
        (cons 40 (/ cispc 2))
        (cons 50 eang)
        (cons 51 sang)
      )
    )
    (setq pt1 pt4
          count (1- count)
    );setq
    );while
  );while
(setq nblk (entmake (list (cons 0 "endblk"))))
(princ (strcat "\nBlock "(if nblk nblk "NOT")" Made\n"))
  (entmake
    (list
      (cons 0 "INSERT")
      (cons 2 nblk)
      (cons 10 (list 0 0 0))
      (cons 8 (getvar"clayer"))
      (cons 70 1)
    )
  )
  (grvecs(eval 'undrw))
(setvar "osmode" osmod)
(princ)
);defun