;;;
;;;
;;;
;;;
;;;****************************************************************************
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 
;;;>		   EDITED: 07-06-2006
;;;
(DEFUN REBAR_ERROR (msg /)
  (SETQ *ERROR* OLD_REBARERROR)
  (PRINC "\nERROR: ")
  (PRINC msg)
  (IF old_osmode
    (SETVAR "OSMODE" old_osmode)
  )
  (IF old_cmdecho
    (SETVAR "CMDECHO" old_cmdecho)
  )
  (PRINC)
) ;_ end of defun
;;;****************************************************************************
(DEFUN c:rebar ()
  (SETQ OLD_REBARERROR *ERROR*)
  (SETQ *error* rebar_error)
  (SETQ old_osmode (GETVAR "OSMODE"))
  (SETVAR "OSMODE" 0)
  (SETQ old_cmdecho (GETVAR "CMDECHO"))
  (SETVAR "CMDECHO" 0)
  (SETQ rebar_ss (SSADD))
  (IF ureal
    nil
    (LOAD "ureal" "File UREAL.LSP not loaded!")
  ) ;_ end of IF
  (SETQ rebarsz (ureal 1
                       ""
                       "Rebar size number"
                       (IF rebarsz
                         rebarsz
                         5
                       ) ;_ end of if
                ) ;_ end of UREAL
  ) ;_ end of SETQ
  (SETQ rebardp1 (ureal 1
                       ""
                       "Rebar depth from 1st face of concrete (0 to skip 1st face)"
                       (IF rebardp1
                         rebardp1
                         2
                       ) ;_ end of if
                ) ;_ end of UREAL
  ) ;_ end of SETQ
  (SETQ rebardp2 (ureal 1
                       ""
                       "Rebar depth from 2nd face of concrete (0 to skip 2nd face)"
                       (IF rebardp2
                         rebardp2
                         2
                       ) ;_ end of if
                ) ;_ end of UREAL
  ) ;_ end of SETQ
  (SETQ rebarsp (ureal 1
                       ""
                       "Rebar spacing"
                       (IF rebarsp
                         rebarsp
                         10
                       ) ;_ end of if
                ) ;_ end of UREAL
  ) ;_ end of SETQ
  (WHILE
    (NOT
      (SETQ concface1 (NENTSELP "\nSelect first wall or slab line: "))
    ) ;_ end of NOT
  ) ;_ end of WHILE
  (SETQ line1 (ENTGET (CAR concface1)))
  (GRDRAW (CDR (ASSOC 10 line1)) (CDR (ASSOC 11 line1)) -1 1)
  (WHILE
    (NOT
      (SETQ concface2 (NENTSELP "\nSelect second wall or slab line: "))
    ) ;_ end of NOT
  ) ;_ end of WHILE
  (SETQ line2 (ENTGET (CAR concface2)))
  (command ".undo" "begin")
  (GRDRAW (CDR (ASSOC 10 line2)) (CDR (ASSOC 11 line2)) -1 1)
  (IF
    (>(DISTANCE (CDR (ASSOC 10 line1)) (CDR (ASSOC 11 line1)))
       (DISTANCE (CDR (ASSOC 10 line2)) (CDR (ASSOC 11 line2))))
     (SETQ outside_line line1
           inside_line (LIST
                         (CONS 10
                           (INTERS
                             (CDR(ASSOC 10 line1))
                             (POLAR(CDR(ASSOC 10 line1))(+(ANGLE(CDR(ASSOC 10 line1))(CDR(ASSOC 11 line1)))(/ pi 2.0))24)
                             (CDR(ASSOC 10 line2))
                             (CDR(ASSOC 11 line2))
                             nil
                           )
                         )
                         (CONS 11
                           (INTERS
                             (CDR(ASSOC 11 line1))
                             (POLAR(CDR(ASSOC 11 line1))(+(ANGLE(CDR(ASSOC 10 line1))(CDR(ASSOC 11 line1)))(/ pi 2.0))24)
                             (CDR(ASSOC 10 line2))
                             (CDR(ASSOC 11 line2))
                             nil
                           )
                         )
                       )
    )
     (SETQ outside_line line2
           inside_line (LIST
                         (CONS 10
                           (INTERS
                             (CDR(ASSOC 10 line2))
                             (POLAR(CDR(ASSOC 10 line2))(+(ANGLE(CDR(ASSOC 10 line2))(CDR(ASSOC 11 line2)))(/ pi 2.0))24)
                             (CDR(ASSOC 10 line1))
                             (CDR(ASSOC 11 line1))
                             nil
                           )
                         )
                         (CONS 11
                           (INTERS
                             (CDR(ASSOC 11 line2))
                             (POLAR(CDR(ASSOC 11 line2))(+(ANGLE(CDR(ASSOC 10 line2))(CDR(ASSOC 11 line2)))(/ pi 2.0))24)
                             (CDR(ASSOC 10 line1))
                             (CDR(ASSOC 11 line1))
                             nil
                           )
                         )
                       )
    )
  )
;;;  (COND
;;;    ((EQUAL (DISTANCE (CDR (ASSOC 10 line1)) (CDR (ASSOC 11 line1)))
;;;            (DISTANCE (CDR (ASSOC 10 line2)) (CDR (ASSOC 11 line2)))
;;;            1.0
;;;     ) ;_ end of EQUAL
;;;     (SETQ inside_line
;;;            line1
;;;           outside_line line2
;;;     ) ;_ end of SETQ
;;;    )
;;;    ((< (DISTANCE (CDR (ASSOC 10 line1)) (CDR (ASSOC 11 line1)))
;;;        (DISTANCE (CDR (ASSOC 10 line2)) (CDR (ASSOC 11 line2)))
;;;     ) ;_ end of <
;;;     (SETQ inside_line
;;;            line1
;;;           outside_line line2
;;;     ) ;_ end of SETQ
;;;    )
;;;    ((> (DISTANCE (CDR (ASSOC 10 line1)) (CDR (ASSOC 11 line1)))
;;;        (DISTANCE (CDR (ASSOC 10 line2)) (CDR (ASSOC 11 line2)))
;;;     ) ;_ end of >
;;;     (SETQ inside_line
;;;            line2
;;;           outside_line line1
;;;     ) ;_ end of SETQ
;;;    )
;;;  ) ;_ end of COND
  (IF(EQ outside_line line1)
    (SETQ osl1 inside_line
          isl2 outside_line
          outside_line osl1
          insiDe_line isl2
    )
  )
  (SETQ
    beglin1pt   (CDR (ASSOC 10 inside_line))
    endlin1pt   (CDR (ASSOC 11 inside_line))
    beglin2pt   (CDR (ASSOC 10 outside_line))
    endlin2pt   (CDR (ASSOC 11 outside_line))
    beglineangl (ANGLE beglin1pt endlin1pt)
  ) ;_ end of SETQ
  (SETQ angl1 (ANGLE
                beglin1pt
                (INTERS beglin1pt
                        (POLAR beglin1pt (+ beglineangl (* 1.5 PI)) 12.0)
                        beglin2pt
                        endlin2pt
                        nil
                ) ;_ end of INTERS
              ) ;_ end of ANGLE
        angl2 (+ angl1 PI)
        dist1 (DISTANCE
                beglin1pt
                (INTERS beglin1pt
                        (POLAR beglin1pt (+ beglineangl (* 1.5 PI)) 12.0)
                        beglin2pt
                        endlin2pt
                        nil
                ) ;_ end of INTERS
              ) ;_ end of DISTANCE
  ) ;_ end of SETQ
  (IF c:mklayr
    nil
    (LOAD "MKLAYR" "File MKLAYR.LSP not loaded!")
  ) ;_ end of IF
  (c:svlayr)
  (SETQ prod  "RBAR"
        mjrg  "S"
        llt   "-"
        colr  "1"
        colra nil
        colri nil
        modf  "SYMB"
  ) ;_ end of SETQ
  (c:mklayr)
  (SETQ begcir1dist
         (+ (/ (REM (DISTANCE beglin1pt endlin1pt) rebarsp) 2.0)
         ) ;_ end of +
  ) ;_ end of SETQ
  (SETQ circle1_pt
                (POLAR (POLAR beglin1pt
                              (ANGLE beglin1pt endlin1pt)
                              (IF (>= (/ (REM (DISTANCE beglin1pt endlin1pt) rebarsp) 2.0) rebardp1)
                                begcir1dist
                                (+ begcir1dist (/ rebarsp 2.0))
                              )
                       ) ;_ end of POLAR
                       angl1
                       (+ rebardp1 (/ rebarsz 16.0))
                ) ;_ end of POLAR
  ) ;_ end of SETQ
  (IF (EQ rebardp1 0)
    NIL
    (PROGN
    (ENTMAKE
      (LIST
        (CONS 0 "LINE")
        (CONS 10 
             (POLAR (POLAR beglin1pt angl1 rebardp1)
                    (ANGLE beglin1pt endlin1pt)
                    2
             ) ;_ end of POLAR
        )
        (CONS 11
             (POLAR (POLAR endlin1pt angl1 rebardp1)
                    (ANGLE endlin1pt beglin1pt)
                    2
             ) ;_ end of POLAR
        )
      )
    )
    (SSADD (ENTLAST) rebar_ss)
    )
;;;    (COMMAND ".LINE"
;;;             (POLAR (POLAR beglin1pt angl1 rebardp1)
;;;                    (ANGLE beglin1pt endlin1pt)
;;;                    2
;;;             ) ;_ end of POLAR
;;;             (POLAR (POLAR endlin1pt angl1 rebardp1)
;;;                    (ANGLE endlin1pt beglin1pt)
;;;                    2
;;;             ) ;_ end of POLAR
;;;             ""
;;;    )
  )
  (IF (EQ rebardp2 0)
    NIL
    (PROGN
    (ENTMAKE
      (LIST
        (CONS 0 "LINE")
        (CONS 10 
             (POLAR (POLAR beglin2pt angl2 rebardp2)
                    (ANGLE beglin2pt endlin2pt)
                    2
             ) ;_ end of POLAR
        )
        (CONS 11
             (POLAR (POLAR endlin2pt angl2 rebardp2)
                    (ANGLE endlin2pt beglin2pt)
                    2
             ) ;_ end of POLAR
        )
      )
    )
    (SSADD (ENTLAST) rebar_ss)
    )
;;;    (COMMAND ".LINE"
;;;             (POLAR (POLAR beglin2pt angl2 rebardp2)
;;;                    (ANGLE beglin2pt endlin2pt)
;;;                    2
;;;             ) ;_ end of POLAR
;;;             (POLAR (POLAR endlin2pt angl2 rebardp2)
;;;                    (ANGLE endlin2pt beglin2pt)
;;;                    2
;;;             ) ;_ end of POLAR
;;;             ""
;;;    ) ;_ end of COMMAND
  )
  (WHILE (< (DISTANCE circle1_pt beglin1pt)
            (DISTANCE beglin1pt endlin1pt)
         ) ;_ end of <
    (IF (EQ rebardp1 0)
      NIL
      (PROGN
        (ENTMAKE
          (LIST
            (CONS 0 "CIRCLE")
            (CONS 10 circle1_pt)
            (CONS 40 (/ rebarsz 16.0))
          )
        )
        (SSADD (ENTLAST) rebar_ss)
      )
;;;      (COMMAND ".CIRCLE" circle1_pt (/ rebarsz 16.0))
    )
    (IF (EQ rebardp2 0)
      NIL
      (PROGN
        (ENTMAKE
          (LIST
            (CONS 0 "CIRCLE")
            (CONS 10
               (POLAR (INTERS circle1_pt
                              (POLAR circle1_pt angl1 12.0)
                              beglin2pt
                              endlin2pt
                              nil
                      ) ;_ end of INTERS
                      angl2
                      (+ rebardp2 (/ rebarsz 16.0))
               ) ;_ end of POLAR
            )
            (CONS 40 (/ rebarsz 16.0))
          )
        )
        (SSADD (ENTLAST) rebar_ss)
      )
;;;      (COMMAND ".CIRCLE"
;;;               (POLAR (INTERS circle1_pt
;;;                              (POLAR circle1_pt angl1 12.0)
;;;                              beglin2pt
;;;                              endlin2pt
;;;                              nil
;;;                      ) ;_ end of INTERS
;;;                      angl2
;;;                      (+ rebardp2 (/ rebarsz 16.0))
;;;               ) ;_ end of POLAR
;;;               (/ rebarsz 16.0)
;;;      ) ;_ end of COMMAND
    )
    (SETQ circle1_pt
           (POLAR circle1_pt (ANGLE beglin1pt endlin1pt) rebarsp)
    ) ;_ end of SETQ
  ) ;_ end of WHILE
  (COMMAND ".REDRAW")
  (command ".undo" "end")
  (c:rslayr)
  (SETQ *ERROR* OLD_REBARERROR)
  (SETVAR "OSMODE" old_osmode)
  (SETVAR "CMDECHO" old_cmdecho)
  (PRINC)
) ;_ end of DEFUN
(DEFUN c:rcorner (/ old_snapang)
  (SETQ OLD_REBARERROR *ERROR*)
  (SETQ *error* rebar_error)
  (SETQ old_osmode (GETVAR "OSMODE"))
  (SETVAR "OSMODE" 0)
  (IF ureal
    nil
    (LOAD "ureal" "File UREAL.LSP not loaded! ")
  ) ;_ end of IF
  (IF upoint
    nil
    (LOAD "upoint" "File UPOINT.LSP not loaded! ")
  ) ;_ end of IF
  (IF ureal
    nil
    (LOAD "ukword" "File UKWORD.LSP not loaded! ")
  ) ;_ end of IF
  (SETQ old_snapang (GETVAR "SNAPANG"))
  (SETQ rebarsz (ureal 1
                       ""
                       "Rebar size number"
                       (IF rebarsz
                         rebarsz
                         5
                       ) ;_ end of if
                ) ;_ end of UREAL
  ) ;_ end of SETQ
  (SETQ rebardp (ureal 1
                       ""
                       "Rebar depth from face of concrete"
                       (IF rebardp
                         rebardp
                         3
                       ) ;_ end of if
                ) ;_ end of UREAL
  ) ;_ end of SETQ
  (PRINC "\nSelect corner lines (4) for rebar: ")
  (PRINC)
  (SETQ corner_ss (SSGET '((0 . "LINE"))))
  (IF (OR
        (> (SSLENGTH corner_ss) 4)
        (< (SSLENGTH corner_ss) 4)
      ) ;_ end of OR
    (PROGN
      (PRINC (STRCAT (IF (> (SSLENGTH corner_ss) 4)
                       "\nToo many"
                       "\nNot enough"
                     ) ;_ end of IF
                     "lines selected ("
                     (ITOA (SSLENGTH corner_ss))
                     " lines selected). "
             ) ;_ end of STRCAT
      ) ;_ end of PRINC
      (PRINC)
    ) ;_ end of PROGN
    (PROGN
      (SETQ ss_count 0)
      (SETQ line_lst nil)
      (WHILE (< ss_count 4)
        (SETQ
          line_lst (APPEND line_lst
                           (LIST (ENTGET (SSNAME corner_ss ss_count)))
                   ) ;_ end of APPEND
        ) ;_ end of SETQ
        (SETQ ss_count (1+ ss_count))
      ) ;_ end of WHILE
      (SETQ line1 (NTH 0 line_lst)
            line2 (NTH 1 line_lst)
            line3 (NTH 2 line_lst)
            line4 (NTH 3 line_lst)
      ) ;_ end of SETQ
      (PRINC "\nAngle line 1 = ")
      (princ (ANGLE (CDR (ASSOC 10 line1)) (CDR (ASSOC 11 line1))))
      (PRINC "\nAngle line 2 = ")
      (princ (ANGLE (CDR (ASSOC 10 line2)) (CDR (ASSOC 11 line2))))
      (PRINC "\nAngle line 3 = ")
      (princ (ANGLE (CDR (ASSOC 10 line3)) (CDR (ASSOC 11 line3))))
      (PRINC "\nAngle line 4 = ")
      (princ (ANGLE (CDR (ASSOC 10 line4)) (CDR (ASSOC 11 line4))))
      (princ)
      (SETQ line1_ang (ANGLE (CDR (ASSOC 10 line1)) (CDR (ASSOC 11 line1)))
            line2_ang (ANGLE (CDR (ASSOC 10 line2)) (CDR (ASSOC 11 line2)))
            line3_ang (ANGLE (CDR (ASSOC 10 line3)) (CDR (ASSOC 11 line3)))
            line4_ang (ANGLE (CDR (ASSOC 10 line4)) (CDR (ASSOC 11 line4)))
      )
      (COND
        ((AND
           (equal (abs(sin line1_ang))(abs(sin line2_ang))0.1)
           (equal (abs(sin line3_ang))(abs(sin line4_ang))0.1)
         ) ;_ end of AND
         (SETQ corn_l1 line1
               corn_l2 line2
               corn_l3 line3
               corn_l4 line4
         ) ;_ end of SETQ
        )
        ((AND
           (equal (abs(sin line1_ang))(abs(sin line3_ang))0.1)
           (equal (abs(sin line2_ang))(abs(sin line4_ang))0.1)
         ) ;_ end of AND
         (SETQ corn_l1 line1
               corn_l2 line3
               corn_l3 line2
               corn_l4 line4
         ) ;_ end of SETQ
        )
        ((AND
           (equal (abs(sin line1_ang))(abs(sin line4_ang))0.1)
           (equal (abs(sin line3_ang))(abs(sin line2_ang))0.1)
         ) ;_ end of AND
         (SETQ corn_l1 line1
               corn_l2 line4
               corn_l3 line2
               corn_l4 line3
         ) ;_ end of SETQ
        )
        (T
         (SETQ corn_l1 nil
               corn_l2 nil
               corn_l3 nil
               corn_l4 nil
         ) ;_ end of SETQ
        )
      ) ;_ end of COND
      (IF (AND corn_l1 corn_l2 corn_l3 corn_l4)
        (PROGN
          (SETQ sec1_bpta (INTERS (CDR (ASSOC 10 corn_l1))
                                  (CDR (ASSOC 11 corn_l1))
                                  (CDR (ASSOC 10 corn_l3))
                                  (CDR (ASSOC 11 corn_l3))
                                  nil
                          ) ;_ end of INTERS
                sec1_bptb (INTERS (CDR (ASSOC 10 corn_l2))
                                  (CDR (ASSOC 11 corn_l2))
                                  (CDR (ASSOC 10 corn_l3))
                                  (CDR (ASSOC 11 corn_l3))
                                  nil
                          ) ;_ end of INTERS
                sec1_bpt  (POLAR sec1_bpta
                                 (ANGLE sec1_bpta sec1_bptb)
                                 (/ (DISTANCE sec1_bpta sec1_bptb) 2.0)
                          ) ;_ end of POLAR
                sec2_bpta (INTERS (CDR (ASSOC 10 corn_l3))
                                  (CDR (ASSOC 11 corn_l3))
                                  (CDR (ASSOC 10 corn_l1))
                                  (CDR (ASSOC 11 corn_l1))
                                  nil
                          ) ;_ end of INTERS
                sec2_bptb (INTERS (CDR (ASSOC 10 corn_l4))
                                  (CDR (ASSOC 11 corn_l4))
                                  (CDR (ASSOC 10 corn_l1))
                                  (CDR (ASSOC 11 corn_l1))
                                  nil
                          ) ;_ end of INTERS
                sec2_bpt  (POLAR sec1_bpta
                                 (ANGLE sec2_bpta sec2_bptb)
                                 (/ (DISTANCE sec2_bpta sec2_bptb) 2.0)
                          ) ;_ end of POLAR
          ) ;_ end of SETQ
          (GRDRAW (CDR (ASSOC 10 corn_l1))
                  (CDR (ASSOC 11 corn_l1))
                  -1
                  1
          ) ;_ end of GRDRAW
          (GRDRAW (CDR (ASSOC 10 corn_l2))
                  (CDR (ASSOC 11 corn_l2))
                  -1
                  1
          ) ;_ end of GRDRAW
          (SETVAR
            "SNAPANG"
            (ANGLE (CDR (ASSOC 10 corn_l1)) (CDR (ASSOC 11 corn_l1)))
          ) ;_ end of SETVAR
          (SETQ
            sec1_ept (upoint
                       1
                       ""
                       "Pick along this section away from intersection"
                       nil
                       sec1_bpt
                      ) ;_ end of upoint
          ) ;_ end of SETQ
          (SETQ sec1_ang (ANGLE sec1_bpt sec1_ept))
          (COMMAND ".REDRAW")
          (GRDRAW (CDR (ASSOC 10 corn_l3))
                  (CDR (ASSOC 11 corn_l3))
                  -1
                  1
          ) ;_ end of GRDRAW
          (GRDRAW (CDR (ASSOC 10 corn_l4))
                  (CDR (ASSOC 11 corn_l4))
                  -1
                  1
          ) ;_ end of GRDRAW
          (SETVAR
            "SNAPANG"
            (ANGLE (CDR (ASSOC 10 corn_l3)) (CDR (ASSOC 11 corn_l3)))
          ) ;_ end of SETVAR
          (SETQ
            sec2_ept (upoint
                       1
                       ""
                       "Pick along this section away from intersection"
                       nil
                       sec2_bpt
                      ) ;_ end of upoint
          ) ;_ end of SETQ
          (SETQ sec2_ang (ANGLE sec2_bpt sec2_ept))
          (COMMAND ".REDRAW")
          (SETQ sec2_thk
                 (ABS (- (DISTANCE sec1_ept
                                   (INTERS sec1_ept
                                           sec1_bpt
                                           (CDR (ASSOC 10 corn_l3))
                                           (CDR (ASSOC 11 corn_l3))
                                           nil
                                   ) ;_ end of INTERS
                         ) ;_ end of DISTANCE
                         (DISTANCE sec1_ept
                                   (INTERS sec1_ept
                                           sec1_bpt
                                           (CDR (ASSOC 10 corn_l4))
                                           (CDR (ASSOC 11 corn_l4))
                                           nil
                                   ) ;_ end of INTERS
                         ) ;_ end of DISTANCE
                      ) ;_ end of -
                 ) ;_ end of ABS
          ) ;_ end of SETQ
          (SETQ sec1_thk
                 (ABS (- (DISTANCE sec2_ept
                                   (INTERS sec2_ept
                                           sec2_bpt
                                           (CDR (ASSOC 10 corn_l1))
                                           (CDR (ASSOC 11 corn_l1))
                                           nil
                                   ) ;_ end of INTERS
                         ) ;_ end of DISTANCE
                         (DISTANCE sec2_ept
                                   (INTERS sec2_ept
                                           sec2_bpt
                                           (CDR (ASSOC 10 corn_l2))
                                           (CDR (ASSOC 11 corn_l2))
                                           nil
                                   ) ;_ end of INTERS
                         ) ;_ end of DISTANCE
                      ) ;_ end of -
                 ) ;_ end of ABS
          ) ;_ end of SETQ
          (IF (> (DISTANCE sec1_ept
                           (INTERS sec1_ept
                                   sec1_bpt
                                   (CDR (ASSOC 10 corn_l3))
                                   (CDR (ASSOC 11 corn_l3))
                                   nil
                           ) ;_ end of INTERS
                 ) ;_ end of DISTANCE
                 (DISTANCE sec1_ept
                           (INTERS sec1_ept
                                   sec1_bpt
                                   (CDR (ASSOC 10 corn_l4))
                                   (CDR (ASSOC 11 corn_l4))
                                   nil
                           ) ;_ end of INTERS
                 ) ;_ end of DISTANCE
              ) ;_ end of >
            (SETQ sec2_in  corn_l4
                  sec2_out corn_l3
            ) ;_ end of SETQ
            (SETQ sec2_in  corn_l3
                  sec2_out corn_l4
            ) ;_ end of SETQ
          ) ;_ end of IF
          (IF (> (DISTANCE sec2_ept
                           (INTERS sec2_ept
                                   sec2_bpt
                                   (CDR (ASSOC 10 corn_l1))
                                   (CDR (ASSOC 11 corn_l1))
                                   nil
                           ) ;_ end of INTERS
                 ) ;_ end of DISTANCE
                 (DISTANCE sec2_ept
                           (INTERS sec2_ept
                                   sec2_bpt
                                   (CDR (ASSOC 10 corn_l2))
                                   (CDR (ASSOC 11 corn_l2))
                                   nil
                           ) ;_ end of INTERS
                 ) ;_ end of DISTANCE
              ) ;_ end of >
            (SETQ sec1_in  corn_l2
                  sec1_out corn_l1
            ) ;_ end of SETQ
            (SETQ sec1_in  corn_l1
                  sec1_out corn_l2
            ) ;_ end of SETQ
          ) ;_ end of IF
;;;          (SETVAR "SNAPANG" (ANGLE (CDR(ASSOC 10 CORN_L1))(CDR(ASSOC 11 CORN_L1))))
;;;          (SETQ SEC1_LPT (upoint 1 "" "projection distance" NIL (INTERS SEC1_EPT SEC1_BPT (CDR(ASSOC 10 SEC2_OUT))(CDR(ASSOC 11 SEC2_OUT))NIL)))
          (SETQ
            sec1_len (- (+ sec2_thk (* 40.0 (/ rebarsz 8.0))) rebardp)
          ) ;_ end of SETQ
          (SETQ sec1_lpt (POLAR (INTERS sec1_ept
                                        sec1_bpt
                                        (CDR (ASSOC 10 sec2_out))
                                        (CDR (ASSOC 11 sec2_out))
                                        nil
                                ) ;_ end of INTERS
                                sec1_ang
                                sec1_len
                         ) ;_ end of POLAR
          ) ;_ end of SETQ
;;;          (SETQ SEC1_LEN (DISTANCE (INTERS SEC1_EPT SEC1_BPT (CDR(ASSOC 10 SEC2_OUT))(CDR(ASSOC 11 SEC2_OUT))NIL) SEC1_LPT))
;;;          (SETVAR "SNAPANG" (ANGLE (CDR(ASSOC 10 CORN_L3))(CDR(ASSOC 11 CORN_L3))))
;;;          (SETQ SEC2_LPT (upoint 1 "" "projection distance" NIL (INTERS SEC2_EPT SEC2_BPT (CDR(ASSOC 10 SEC1_OUT))(CDR(ASSOC 11 SEC1_OUT))NIL)))
          (SETQ
            sec2_len (- (+ sec1_thk (* 40.0 (/ rebarsz 8.0))) rebardp)
          ) ;_ end of SETQ
          (SETQ sec2_lpt (POLAR (INTERS sec2_ept
                                        sec2_bpt
                                        (CDR (ASSOC 10 sec1_out))
                                        (CDR (ASSOC 11 sec1_out))
                                        nil
                                ) ;_ end of INTERS
                                sec2_ang
                                sec2_len
                         ) ;_ end of POLAR
          ) ;_ end of SETQ
;;;          (SETQ SEC2_LEN (DISTANCE (INTERS SEC2_EPT SEC2_BPT (CDR(ASSOC 10 SEC1_OUT))(CDR(ASSOC 11 SEC1_OUT))NIL) SEC2_LPT))
          (SETQ
            rstyle (ukword 1
                           "Crossing Parallel"
                           "Corner rebar style [Crossing, Parallel]"
                           (IF rstyle
                             rstyle
                             "Crossing"
                           ) ;_ end of IF
                   ) ;_ end of ukword
          ) ;_ end of SETQ
          (IF c:mklayr
            nil
            (LOAD "MKLAYR" "File MKLAYR.LSP not loaded!")
          ) ;_ end of IF
          (c:svlayr)
          (SETQ mjrg  "S"
                llt   "-"
                prod  "RBAR"
                colr  "4"
                colra nil
                colri nil
                modf  "SYMB"
          ) ;_ end of SETQ
          (c:mklayr)
          (IF (EQ rstyle "Crossing")
            (PROGN
              (SETQ rbar1_pt1 (POLAR sec1_lpt
                                     sec2_ang
                                     (- (/ sec1_thk 2.0) rebardp)
                              ) ;_ end of POLAR
                    rbar1_pt2 (POLAR rbar1_pt1
                                     (+ sec1_ang PI)
                                     (- sec1_len rebardp 2.0)
                              ) ;_ end of POLAR
                    rbar1_pt3 (POLAR rbar1_pt2 (+ sec1_ang PI) 2.0)
                    rbar1_pt4 (POLAR rbar1_pt3 sec2_ang 2.0)
                    rbar1_pt5 (POLAR rbar1_pt4
                                     sec2_ang
                                     (+ (- sec2_len sec1_thk 2.0) rebardp)
                              ) ;_ end of POLAR
                    rcir1_pt1 (POLAR (POLAR rbar1_pt3 sec1_ang 0.5)
                                     sec2_ang
                                     0.5
                              ) ;_ end of POLAR
                    rbar2_pt1 (POLAR rbar1_pt1
                                     (+ sec2_ang PI)
                                     (- sec1_thk (* 2.0 rebardp))
                              ) ;_ end of POLAR
                    rbar2_pt2 (POLAR rbar2_pt1
                                     (+ sec1_ang PI)
                                     (+ (- sec1_len sec2_thk 2.0) rebardp)
                              ) ;_ end of POLAR
                    rbar2_pt3 (POLAR rbar2_pt2 (+ sec1_ang PI) 2.0)
                    rbar2_pt4 (POLAR rbar2_pt3 sec2_ang 2.0)
                    rbar2_pt5 (POLAR rbar2_pt4
                                     sec2_ang
                                     (- sec2_len rebardp 2.0)
                              ) ;_ end of POLAR
                    rcir2_pt1 (POLAR (POLAR rbar2_pt3 sec2_ang 0.5)
                                     sec1_ang
                                     0.5
                              ) ;_ end of POLAR
              ) ;_ end of SETQ
              (COMMAND ".PLINE"    rbar1_pt1   rbar1_pt2   "A"
                       rbar1_pt4   "L"         rbar1_pt5   ""
                       ".PLINE"    rbar2_pt1   rbar2_pt2   "A"
                       rbar2_pt4   "L"         rbar2_pt5   ""
                      ) ;_ end of COMMAND
            ) ;_ end of PROGN
            (PROGN
              (SETQ rbar1_pt1 (POLAR sec1_lpt
                                     sec2_ang
                                     (- (/ sec1_thk 2.0) rebardp)
                              ) ;_ end of POLAR
                    rbar1_pt2 (POLAR rbar1_pt1
                                     (+ sec1_ang PI)
                                     (+ (- sec1_len sec2_thk 2.0) rebardp)
                              ) ;_ end of POLAR
                    rbar1_pt3 (POLAR rbar1_pt2 (+ sec1_ang PI) 2.0)
                    rbar1_pt4 (POLAR rbar1_pt3 sec2_ang 2.0)
                    rbar1_pt5 (POLAR rbar1_pt4
                                     sec2_ang
                                     (+ (- sec2_len sec1_thk 2.0) rebardp)
                              ) ;_ end of POLAR
                    rbar2_pt1 (POLAR rbar1_pt1
                                     (+ sec2_ang PI)
                                     (- sec1_thk (* 2.0 rebardp))
                              ) ;_ end of POLAR
                    rbar2_pt2 (POLAR rbar2_pt1
                                     (+ sec1_ang PI)
                                     (- sec1_len rebardp 2.0)
                              ) ;_ end of POLAR
                    rbar2_pt3 (POLAR rbar2_pt2 (+ sec1_ang PI) 2.0)
                    rbar2_pt4 (POLAR rbar2_pt3 sec2_ang 2.0)
                    rbar2_pt5 (POLAR rbar2_pt4
                                     sec2_ang
                                     (- sec2_len rebardp 2.0)
                              ) ;_ end of POLAR
              ) ;_ end of SETQ
              (COMMAND ".PLINE"    rbar1_pt1   rbar1_pt2   "A"
                       rbar1_pt4   "L"         rbar1_pt5   ""
                       ".PLINE"    rbar2_pt1   rbar2_pt2   "A"
                       rbar2_pt4   "L"         rbar2_pt5   ""
                      ) ;_ end of COMMAND
            ) ;_ end of PROGN
          ) ;_ end of IF
        ) ;_ end of PROGN
        (PROGN
          (PRINC
            "\nLines are not in parallel pairs, function cancelled! "
          ) ;_ end of PRINC
          (PRINC)
        ) ;_ end of PROGN
      ) ;_ end of IF
    ) ;_ end of PROGN
  ) ;_ end of IF
  (SETQ *ERROR* OLD_REBARERROR)
  (SETVAR "SNAPANG" old_snapang)
  (c:rslayr)
  (SETVAR "OSMODE" old_osmode)
  (PRINC)
) ;_ end of DEFUN

;|«Visual LISP© Format Options»
(72 2 40 2 T "end of " 60 9 2 1 0 nil T nil T)
;*** DO NOT add text below the comment! ***|;