;;;Place spot elevation X's and text. (uses GETSTYLE UPOINT USTR)
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 4-16-95
;;;>		   EDITED: 04-30-2004
;;;
(DEFUN C:SPOT
       (/ ipt str txs tip htx x1 x2 x3 x4 clayr dimsc atxht txht)
  (SETVAR "cmdecho" 0)
  (SETQ	clayr (GETVAR "clayer")
  )					;setq
  (IF getstyle
    (getstyle "A")
    (PROGN (LOAD "getstyle") (getstyle "A"))
  ) ;_ end of if
  (IF dimscl
    nil
    (LOAD "dimscl")
  ) ;_ end of IF
  (IF txtsize
    nil
    (LOAD "txtsize")
  ) ;_ end of IF
  (IF (AND
	txtsize
	dimscl
      ) ;_ end of and
    (PROGN
      (dimscl)
      (txtsize nil)
      (WHILE
	(SETQ ipt (upoint 0 "" "\nEnter point to label " nil nil))
	 (PROGN
	   (SETQ cvtwst10 (GETVAR "viewtwist"))
	   (SETQ unangl10 (-(* 2.0 PI)cvtwst10))
	   (SETQ
	     tip (POLAR ipt (+ unangl10 (/ PI 2)) txtht)
	     htx (/ txtht 2)
	     x1	 (POLAR ipt (+ unangl10 (* 0.75 PI)) htx)
	     x2	 (POLAR ipt (+ unangl10 (* 1.75 PI)) htx)
	     x3	 (POLAR ipt (+ unangl10 (* 1.25 PI)) htx)
	     x4	 (POLAR ipt (+ unangl10 (* 0.25 PI)) htx)
	   )
	   (PROGN
	     (SETQ str (ustr 1 "\nEnter elevation " str nil))
	     (COMMAND)
	     (COMMAND ".layer" "m" "C-SPOT6NOTE" "c" 6 "" "")
	     (COMMAND ".line" x1 x2 "")
	     (COMMAND ".line" x3 x4 "")
	     (COMMAND ".text" tip txtht (* 180.0 (/ unangl10 PI)) str)
	   )				;progn
	 )				;progn
      )					;while
    ) ;_ end of progn
    (COND
      ((AND (NOT dimscl) (NOT txtsize))
       (PRINC "\nFile DIMSCL.LSP not loaded ")
       (PRINC "\nFile TXTSIZE.LSP not loaded ")
      )
      ((NOT dimscl)
       (PRINC "\nFile DIMSCL.LSP not loaded ")
      )
      ((NOT txtsize)
       (PRINC "\nFile TXTSIZE.LSP not loaded ")
      )
    ) ;_ end of cond
  ) ;_ end of if
  (SETVAR "clayer" clayr)
  (getstyle "")
  (SETVAR "cmdecho" 1)
  (COMMAND)
)					;defun
;|«Visual LISP© Format Options»
(72 2 40 2 T "end of " 60 9 2 0 0 T T nil T)
;*** DO NOT add text below the comment! ***|;