;;;
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 
;;;>		   EDITED: 10-17-2005
;;;
(DEFUN spt_error (msg /)
  (SETQ *error* (IF oldspt_error
                  oldspt_error
                  NIL
                ) ;_ end of IF
  ) ;_ end of SETQ
  (IF (WCMATCH msg "bad argument type: *")
    (PRINC "\nNo AECC_POINT object selected! ")
    (PRINC msg)
  )
;;;  (princ "\n")
;;;  (princ dopt)
  (PRINC)
) ;_ end of DEFUN
;;;********************************************************************
(DEFUN C:SPT ()
;;;If vars do_tnote is T and typ_t# is a string then MLT will automatically use typ_t# as the text. (# represents the line ordered string)
  (SETQ oldspt_error *error*)
  (SETQ *error* spt_error)
  (SETQ	donefun	nil
	do_tnote T
  ) ;_ end of setq
  (SETQ it (NENTSELP))
  (SETQ ename (CAR it))
  (SETQ edata (ENTGET ename))
  (IF (EQ (CDR (ASSOC 0 edata)) "AECC_POINT")
    (PROGN
      (SETQ lname (CDR (ASSOC 8 edata)))
      (SETQ nselp (CADR it))
      (SETQ pt11 (CDR (ASSOC 11 edata)))
      (SETQ pt11x (CAR pt11))
      (SETQ pt11y (CADR pt11))
      (SETQ pt11z (CADDR pt11))
      (SETQ pt90 (CDR (ASSOC 90 edata)))
      (SETQ pt302 (CDR (ASSOC 302 edata)))
      (SETQ pt303 (CDR (ASSOC 303 edata)))
      (SETQ typ_t1 pt90
	    typ_t2 (STRCAT "N " (RTOS pt11y 2))
	    typ_t3 (STRCAT "E " (RTOS pt11x 2))
	    typ_t4 (STRCAT "ELEV. " (RTOS pt11z 2))
	    typ_t5 pt302
      ) ;_ end of setq
      (SETQ spt_dlg# (LOAD_DIALOG "spt"))
      (SETQ newdlg_spt
	     (NEW_DIALOG
	       "spt"
	       spt_dlg#
	       (IF defact_spt
		 defact_spt
		 ""
	       ) ;_ end of IF
	       (IF spt_loc
		 spt_loc
		 '(-1 -1)
	       ) ;_ end of IF
	     ) ;_ end of NEW_DIALOG
      ) ;_ end of SETQ
      (IF errmsg
	(SET_TILE "error" errmsg)
      ) ;_ end of IF
      (SET_TILE "pt11x" (RTOS pt11x 2 4))
      (SET_TILE "pt11y" (RTOS pt11y 2 4))
      (SET_TILE "pt11z" (RTOS pt11z 2 4))
      (SET_TILE "pt90" (ITOA pt90))
      (SET_TILE "pt302" pt302)
      (SET_TILE "pt303" pt303)
      (ACTION_TILE "pt303" "(SETQ typ_t6 (GET_TILE \"pt303\"))")
      (ACTION_TILE "cancel" "(reset_typ)(setq spt_loc (done_dialog 0))")
      (ACTION_TILE
	"accept"
	"(setq donefun c:mlt)(setq spt_loc (done_dialog 0))"
      ) ;_ end of ACTION_TILE
      (START_DIALOG)
      (UNLOAD_DIALOG spt_dlg#)
      (IF donefun
	(donefun)
      ) ;_ end of IF
    ) ;_ end of progn
    (PROGN
      (PRINC "\nNo AECC_POINT object selected. ")
      (PRINC)
    ) ;_ end of progn
  ) ;_ end of if
  (SETQ do_tnote NIL)
  (IF oldspt_error
    (SETQ *error* oldspt_error)
    (SETQ *error* NIL)
  )
  (PRINC)
) ;_ end of DEFUN
(defun reset_typ ()
      (SETQ typ_t1 ""
	    typ_t2 ""
	    typ_t3 ""
	    typ_t4 ""
	    typ_t5 ""
      ) ;_ end of setq
  (PRINC)
)
 ;|«Visual LISP© Format Options»
(72 2 40 2 T "end of " 60 9 2 0 0 T T nil T)
;*** DO NOT add text below the comment! ***|;