;;;Modify the text obliquing angle of a selection set of text entities. (uses UREAL
;;;       The only input required is the desired
;;;       text obliquing angle and selection of the text to modify.  There
;;;       is no need to worry about not selecting non-text entities
;;;       because they will be automatically filtered out of the
;;;       selection set.
;;;
;;;              
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 6-7-94
;;;>		   EDITED: 01-24-2006
;;;
(DEFUN C:TXANG (/ tset tsln cntr tent edtw)
  (IF ureal NIL (LOAD "ureal" "\nFile UREAL.LSP not loaded! "))
  (IF ukword NIL (LOAD "ukword" "\nFile UKWORD.LSP not loaded! "))
  (SETQ	txtoa (* (/ (ureal 1
			   ""
			   "\nText Obliquing Angle "
			   (IF txtoa
			     (* (/ txtoa PI) 180)
			     15
			   ) ;_ end of if
		    ) ;_ end of ureal
		    180.0000
		 ) ;_ end of /
		 PI
	      ) ;_ end of *
  ) ;_ end of setq
  (PROMPT "\nSelect Text: ")
  (SETQ tset (SSGET '((-4 . "<OR")(0 . "TEXT")(0 . "ATTDEF")(0 . "INSERT")(-4 . "OR>"))))
  (IF tset
    (PROGN
      (SETQ tsln (SSLENGTH tset))
      (SETQ cntr 0)
    ) ;_ end of progn
  ) ;_ end of if
  (WHILE
    (IF	(AND (< cntr tsln) tset)
      (SETQ tent (ENTGET (SSNAME tset cntr)))
    )					;if
     (PROGN
       (SETQ edtw (ENTGET (CDAR tent)))
       (IF (OR (EQ (CDR (ASSOC 0 edtw)) "TEXT")
	       (EQ (CDR (ASSOC 0 edtw)) "ATTDEF")
	   ) ;_ end of OR
	 (PROGN
	   (SETQ edtw
		  (SUBST (CONS 51 txtoa)
			 (ASSOC 51 edtw)
			 edtw
		  ) ;_ end of subst
	   ) ;_ end of setq
	   (ENTMOD edtw)
	 ) ;_ end of progn
       ) ;_ end of if
       (IF (EQ (CDR (ASSOC 0 edtw)) "INSERT")
	 (PROGN
	   (SETQ ins_edtw edtw)
	 (WHILE (/=(CDR(ASSOC 0(ENTGET(ENTNEXT(CDR(ASSOC -1 EDTW))))))"SEQEND")
	   (SETQ edtw (ENTGET(ENTNEXT(CDR(ASSOC -1 EDTW)))))
	   (IF(EQ (CDR (ASSOC 0 edtw)) "ATTRIB")
	 (PROGN
	   (REDRAW (CDR(ASSOC -1 EDTW)) 3)
	   (SETQ setthisoblique (ukword 1 "Yes No" "Modify this attribute's oblique angle?" (IF setthisoblique setthisoblique "Yes")))
	   (IF (EQ setthisoblique "Yes")
	     (PROGN
	   (SETQ edtw
		  (SUBST (CONS 51 txtoa)
			 (ASSOC 51 edtw)
			 edtw
		  ) ;_ end of subst
	   ) ;_ end of setq
	   (ENTMOD edtw)
	   (ENTUPD (CDR(ASSOC -1 edtw)))
	   ))
	   (REDRAW (CDR(ASSOC -1 EDTW)) 4)
	 ) ;_ end of progn
	     ))
;;;	   (ENTUPD ins_edtw)
	   )
       ) ;_ end of if
       (SETQ cntr (1+ cntr))
     ) ;_ end of progn
  ) ;_ end of while
)					;DEFUN

;|«Visual LISP© Format Options» (72 2 40 2 T "end of " 60 9 2 0 0 T T nil T)
 ***Don't add text below the comment!***|;