;;;Change text in blocks to separate layer (*-TXT) from other entities.
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 2001
;;;>		   EDITED: 08-27-2001
;;;
(DEFUN c:txtblks ()
  (SETQ blk_list (LIST (CDR (ASSOC 2 (TBLNEXT "BLOCK" T)))))
  (WHILE (SETQ next_blk (TBLNEXT "BLOCK"))
    (SETQ blk_list (APPEND blk_list (LIST (CDR (ASSOC 2 next_blk)))))
  ) ;_ end of WHILE
  (SETQ txblk_lst nil
        blk_ename nil
  ) ;_ end of SETQ
  (FOREACH n blk_list
    (SETQ blk_ename (CDR (ASSOC -2 (TBLSEARCH "BLOCK" n))))
    (SETQ has_text nil
          def_list nil
          blk_lays nil)
    (WHILE (AND blk_ename
                (NOT (EQ (CDR (ASSOC 0 (ENTGET blk_ename))) "ENDBLK"))
           ) ;_ end of AND
      (SETQ cent_list (ENTGET blk_ename))
      (IF (EQ (CDR (ASSOC 0 cent_list)) "TEXT")
        (PROGN
          (SETQ has_text T)
          (IF (OR
                (WCMATCH(CDR(ASSOC 8 cent_list))"*-TXT")
                (WCMATCH(CDR(ASSOC 8 cent_list))"*TEXT*")
              )
            NIL
            (SETQ cent_list (SUBST (CONS 8
                                         (IF (EQ (CDR(ASSOC 8 cent_list)) "0")
                                           (STRCAT n "-TXT")
                                           (STRCAT(CDR(ASSOC 8 cent_list))"-TXT")
                                         ))
                                   (ASSOC 8 cent_list)
                                   cent_list))
          )
        )
      ) ;_ end of IF
      (IF def_list
        (SETQ def_list (APPEND def_list (LIST cent_list)))
        (SETQ def_list (list (append (list nil) (reverse(cdr(reverse(TBLSEARCH "BLOCK" n))))) cent_list))
      )
      (SETQ blk_ename (ENTNEXT blk_ename))
    ) ;_ end of WHILE
    (IF (and def_list has_text)
      (PROGN
        (SETQ def_list (APPEND def_list (LIST (LIST nil (CONS 0 "ENDBLK")))))
        (FOREACH r def_list
          (ENTMAKE (CDR r))
        )
      )
    )
  ) ;_ end of FOREACH
  (princ "\nRedefined blocks require a regen to view changes.")
  (PRINC)
) ;_ end of DEFUN

;|«Visual LISP© Format Options» (72 2 40 2 T "end of " 60 9 2 1 0 nil nil nil T)
 ***Don't add text below the comment!***|;