;;;
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 12-20-94
;;;>		   EDITED: 12-05-2006
;;;
(DEFUN save_file_chk ()
  (SETQ	princprfx (IF princprfx
		    (STRCAT princprfx "  ")
		    "[DEBUG]  "
		  ) ;_ end of IF
  ) ;_ end of SETQ
  (IF princdebugstrs
    nil
    (LOAD "princdebugstrs" "\nFile PRINCDEBUGSTRS.LSP not loaded! ")
  ) ;_ end of IF
  (princdebugstrs (LIST "Begin execution of SAVE_FILE_CHK function.\n"))
  (IF
    (OR
      mydbunmod
      (AND
        (NOT (EQ (BOOLE 1  1 (GETVAR "dbmod")) 1))
        (NOT (EQ (BOOLE 1  8 (GETVAR "dbmod")) 8))
        (NOT (EQ (BOOLE 1  16 (GETVAR "dbmod")) 16))
      )
      (EQ (GETVAR "dwgname") "DRAWING.DWG")
      (WCMATCH (STRCASE (GETVAR "dwgname")) "DRAWING#.DWG")
      (WCMATCH (STRCASE (GETVAR "dwgname")) "DRAWING##.DWG")
    ) ;_ end of OR
     (SETQ save_this nil)
     (PROGN
       (SETQ what_to_do   ; Question "Save changes to...?" Returns: 6=Yes, 3=No, or 1=Cancel
              (DOS_MSGBOX
                (STRCAT "Save changes to "
                        (GETVAR "dwgprefix")
                        (GETVAR "dwgname")
                ) ;_ end of strcat
                "AutoCAD"
                5
                1
              ) ;_ end of dos_msgbox
       ) ;_ end of SETQ
       (COND
         ((EQ what_to_do 6); "Save changes...?" Yes (or "Discard changes...?" No)
          (SETQ save_this T)
          (IF (OR (EQ (GETVAR "dwgname") "DRAWING.DWG")
                  (WCMATCH (GETVAR "dwgname") "DRAWING#.DWG")
              ) ;_ end of OR
            (COMMAND ".saveas" "" "~")
            (IF c:qsave
              (c:qsave)
              (COMMAND ".qsave")
            ) ;_ end of IF
          ) ;_ end of IF
          (IF (EQ (GETVAR "DBMOD") 0)
            (SETQ what_to_do nil
                  save_this nil
            )
          ))
         ((EQ what_to_do 3); "Save changes...?" No (or "Discard changes...?" Yes)
;;;          (SETQ what_to_do nil)
          (SETQ save_this nil))
       ) ;_ end of COND
     ) ;_ end of PROGN
  ) ;_ end of IF
  (princdebugstrs (LIST "End execution of SAVE_FILE_CHK function.\n"))
  (SETQ	princprfx
	 (COND
	   ((AND princprfx (WCMATCH princprfx "`[DEBUG`]   *"))
	    (SUBSTR princprfx 1 (- (STRLEN princprfx) 2))
	   )
	   (T "[DEBUG]  ")
	 ) ;_ end of COND
  ) ;_ end of SETQ
  (PRINC)
) ;_ end of DEFUN