;;;Modify the text height of a selection set of text entities. (uses USTR)
;;;       The only input required is the desired
;;;       text width factor and selection of the text to modify.  There
;;;       is no need to worry about not selecting non-text entities
;;;       because they will be automatically filtered out of the
;;;       selection set.
;;;
;;;              
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 6-7-94
;;;>		   EDITED: 07-07-2005
;;;
(DEFUN C:thgt (/ tht tset tsln cntr tent edtw)
  (IF ustr
    nil
    (LOAD "ustr" "\nFile USTR.LSP not loaded! ")
  ) ;_ end of if
  (SETQ	thts (ustr 1
		   "\n\"Leroy Template Size\" or Standard(=110) "
		   (IF thts
		     thts
		     "Standard"
		   ) ;_ end of if
		   nil
	     ) ;_ end of ustr
  ) ;_ end of setq
  (IF dimscl
    nil
    (LOAD "dimscl")
  ) ;_ end of if
  (dimscl)
  (IF (OR (EQ (SUBSTR thts 1 1) "S") (EQ (SUBSTR thts 1 1) "s"))
    (SETQ tht (* 0.110 dimsc))
    (SETQ tht (* (* (ATOI thts) 0.001) dimsc))
  )					;if
  (PROMPT "\nSelect Text: ")
  (SETQ	tset (SSGET '((-4 . "<or")
		      (-4 . "<and")
		      (0 . "INSERT")
		      (66 . 1)
		      (-4 . "and>")
		      (0 . "TEXT")
		      (0 . "ATTDEF")
		      (0 . "ATTRIB")
		      (-4 . "or>")
		     )
	     ) ;_ end of ssget
  ) ;_ end of setq
  (IF tset
    (PROGN
      (SETQ tsln (SSLENGTH tset))
      (SETQ cntr 0)
    ) ;_ end of progn
  ) ;_ end of if
  (WHILE
    (IF	(AND (< cntr tsln) tset)
      (SETQ tent (ENTGET (SSNAME tset cntr)))
    )					;if
     (PROGN
       (SETQ edtw (ENTGET (CDAR tent)))
       (IF (OR
	     (EQ (CDR (ASSOC 0 edtw)) "TEXT")
	     (EQ (CDR (ASSOC 0 edtw)) "ATTRIB")
	     (EQ (CDR (ASSOC 0 edtw)) "ATTDEF")
	   )				;or
	 (PROGN
	   (SETQ edtw
		  (SUBST (CONS 40 tht)
			 (ASSOC 40 edtw)
			 edtw
		  ) ;_ end of subst
	   ) ;_ end of setq
	   (ENTMOD edtw)
	 ) ;_ end of progn
	 (IF (EQ (CDR (ASSOC 0 edtw)) "INSERT")
	   (WHILE (/= (CDR (ASSOC 0 edtw)) "SEQEND")
	     (IF (EQ (CDR (ASSOC 0 edtw)) "ATTRIB")
	       (PROGN
		 (SETQ edtw
			(SUBST (CONS 40 tht)
			       (ASSOC 40 edtw)
			       edtw
			) ;_ end of subst
		 ) ;_ end of setq
		 (ENTMOD edtw)
		 (ENTUPD (CDR (ASSOC -1 edtw)))
	       ) ;_ end of progn
	     ) ;_ end of if
	     (SETQ edtw (ENTGET (ENTNEXT (CDR (ASSOC -1 edtw)))))
	   ) ;_ end of while
	 ) ;_ end of if
       ) ;_ end of if
       (SETQ cntr (1+ cntr))
     ) ;_ end of progn
  ) ;_ end of while
)					;DEFUN
;|«Visual LISP© Format Options»
(72 2 40 2 T "end of " 60 9 2 0 0 T T nil T)
;*** DO NOT add text below the comment! ***|;