;;;Finds entities on layers having linetypes with embedded text and
;;;entities whose linetypes have embedded text and changes their
;;;thickness to 1.0 so they will hide properly with hidden line removal.
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 5/25/01
;;;>		   EDITED: 05-25-2001
;;;
(defun c:thkfix ( / lt_name lt_def ltype_lst ltsrch_lst la_name la_lst)
  (if wipeprom nil (load "wipeprom" "\nFile WIPEPROM.LSP not found! "))
  (tblnext "ltype" T)
  (princ "\n  Finding linetypes with embedded text... ")
  (while (setq lt_name (tblnext "ltype" nil))
    (setq lt_def (entget (tblobjname "Ltype" (cdr (assoc 2 lt_name)))))
    (if (assoc 9 lt_def)
      (if ltype_lst
        (setq ltype_lst (append ltype_lst (list (cdr (assoc 2 lt_def)))))
        (setq ltype_lst (list (cdr (assoc 2 lt_def))))
      )
    )
  )
  (if ltype_lst
    (progn
      (setq ltsrch_lst (mapcar '(lambda (x) (cons 6 x)) ltype_lst))
      (setq la_name (tblnext "layer" T))
      (if (member (cdr (assoc 6 la_name)) ltype_lst)
        (setq la_lst (list (cons 8 (cdr (assoc 2 la_name)))))
      )
      (wipeprom)
      (princ "  Finding layers with those linetypes... ")
      (while (setq la_name (tblnext "layer" nil))
        (if (member (cdr (assoc 6 la_name)) ltype_lst)
          (if la_lst
            (setq la_lst (append la_lst (list (cons 8 (cdr (assoc 2 la_name))))))
            (setq la_lst (list (cons 8 (cdr (assoc 2 la_name)))))
          )
        )
      )
      (if la_lst
        (progn
          (wipeprom)
          (PRINC "  Finding entities on those layers or with those linetypes... ")
          (setq srch_lst (append (list (cons -4 "<OR")) ltsrch_lst la_lst (list (cons -4 "OR>"))))
          (setq ent_ss (ssget "X" srch_lst ))
          (if ent_ss
            (progn
              (command "_.change" ent_ss "" "P" "T" 1.0 "")
              (wipeprom)
              (princ (strcat "  " (itoa (sslength ent_ss)) " entities' Thickness changed to 1.0                                "))
            )
            (progn
              (wipeprom)
              (princ "  No entities found on those layers!                                  ")
            )
          )
        )
        (progn
          (wipeprom)
          (princ "  No layers found with those linetypes!                               ")
        )
      )
    )
    (progn
      (wipeprom)
      (princ "  No linetypes found with embedded text!                              ")
    )
  )
  (princ)
)
(princ)