;;;Dialog utility for storing, editing and retrieving/placing Typical Notes into a drawing.
;;;
;;;>	Author:	Henry C. Francis
;;;>		425 N. Ashe St.
;;;>		Southern Pines, NC 28387
;;;>		http://paracadd.com
;;;>		All rights reserved.
;;;
;;;>		COPYRIGHT: 2/1995
;;;>		   EDITED: 09-02-2006
;;;
(defun TNOTE_ERROR (msg / )
  (done_dialog)
  (TERM_DIALOG)
  (IF old_tnoterror
    (SETQ *ERROR* old_tnoterror)
  )
  (PRINC "\nERROR: ")
  (PRINC msg)
  (IF getstyle (getstyle ""))
  (PRINC)
)
(DEFUN c:tnote (/ tn_pl_note new_tnote_list)
  (SETQ old_tnoterror *ERROR*)
  (IF getstyle NIL (LOAD "getstyle" "\nFile GETSTYLE.LSP not loaded! "))
  (IF getstyle (getstyle "A"))
  (setq mystartcdate (getvar"cdate"))
  (SETQ quit_clg nil)
  (SETQ count 0)
  (IF browser_help NIL (LOAD "browser_help" "\nFile BROWSER_HELP not loaded!"))
  (SETQ tn_num (LOAD_DIALOG "tnote"))
  (NEW_DIALOG "tnote" tn_num)
  (SETQ tn_thts
    (IF tn_thts tn_thts (IF do_cmud "100" "110"))
  )
  (SET_TILE "leroy_size" tn_thts)
  (set_leroy tn_thts)
  (SET_TILE "tn_space"
	    (COND
	      ((AND (EQ (GETVAR "tilemode") 0)
		     tn_space
		     (OR (EQ tn_space "tn_psp") (EQ tn_space "tn_csp")))
		     tn_space
	      )
	      ((AND (EQ (GETVAR "tilemode") 1)
		     tn_space
		     (OR (EQ tn_space "tn_msp") (EQ tn_space "tn_csp")))
		     tn_space
	      )
	      (T (SETQ tn_space "tn_msp"))
	    )
  ) ;_ end of SET_TILE
  (SET_TILE "colr_over"
	    (IF tn_colr_over
	      tn_colr_over
	      "0"
	    )
  )
  (SET_TILE "ldrc_value"
	    (IF tnote_ldrc
	      tnote_ldrc
	      "2"
	    )
  )
  (SET_TILE "txtc_value"
	    (IF tnote_txtc
	      tnote_txtc
	      "3"
	    )
  )
  (SET_TILE "ldr_slide"
	    (IF tnote_ldrc
	      tnote_ldrc
	      "2"
	    )
  )
  (SET_TILE "txt_slide"
	    (IF tnote_txtc
	      tnote_txtc
	      "3"
	    )
  )
  (SET_TILE "t-leader"
	    (IF t-leader
	      t-leader
	      "0"
	    )
  )
  (set_colr_mode)
  (SET_TILE "add_bubble"
	    (IF	tn_add_bubble
	      tn_add_bubble
	      "0"
	    ) ;_ end of if
  ) ;_ end of set_tile
  (SET_TILE "detail_desg"
	    (IF	tn_detail_desg
	      tn_detail_desg
	      ""
	    ) ;_ end of if
  ) ;_ end of set_tile
  (SET_TILE "sheet_locn"
	    (IF	tn_sheet_locn
	      tn_sheet_locn
	      ""
	    ) ;_ end of if
  ) ;_ end of set_tile
  (IF (OR (NOT tn_add_bubble) (EQ tn_add_bubble "0"))
    (PROGN
      (MODE_TILE "detail_desg" 1)
      (MODE_TILE "sheet_locn" 1)
    ) ;_ end of progn
    (PROGN
      (MODE_TILE "detail_desg" 0)
      (MODE_TILE "sheet_locn" 0)
    ) ;_ end of progn
  ) ;_ end of if
  (IF (AND
	sel_key
	(EQ (TYPE sel_key) 'STR)
	(EQ (TYPE (READ sel_key)) 'INT)
	tnote_list
	(> (LENGTH tnote_list)(READ sel_key))
      )
    (PROGN
      (SET_TILE "new_item" (NTH (READ sel_key) tnote_list))
      (tn_set_caps)
      (set_pview)
    )
  )
  (ACTION_TILE "Browse_datf" "(get_dat_file)")
  (ACTION_TILE
    "Major"
    "(setq sel_key(get_tile\"Major\"))(set_tnote_ebox)(setq tn_newitem(get_tile\"new_item\"))(set_wrap)(set_pview)(if(eq $reason 4)(progn(set_bubl)(setq tn_pl_note T tnpset_size(get_tile\"leroy_size\"))(done_dialog)))"
  ) ;_ end of action_tile
  (ACTION_TILE "Search" "(setq tn_srch_str (strcat \"*\"(get_tile \"new_item\")\"*\"))(srch_tnlist)")
  (ACTION_TILE "tn_space" "(setq tn_space (get_tile\"tn_space\"))")
  (ACTION_TILE
    "force_caps"
    "(setq tn_fcaps (get_tile \"force_caps\"))(tn_set_caps)"
  ) ;_ end of action_tile
  (ACTION_TILE
    "new_item"
    "(setq tn_newitem (get_tile \"new_item\"))(tn_set_caps)(set_pview)"
  ) ;_ end of action_tile
  (ACTION_TILE
    "Wrap_slide"
    "(setq tn_wrap_len(get_tile\"Wrap_slide\"))(set_tile\"Wrap_value\"tn_wrap_len)(setq tn_newitem(get_tile\"new_item\"))(set_bubl)(set_pview)"
  ) ;_ end of action_tile
  (ACTION_TILE "t-leader" "(setq t-leader (get_tile\"t-leader\"))")
  (ACTION_TILE
    "Wrap_value"
    "(setq tn_wrap_len(get_tile\"Wrap_value\"))(set_tile\"Wrap_slide\"tn_wrap_len)(setq tn_newitem(get_tile\"new_item\"))(set_bubl)(set_pview)"
  ) ;_ end of action_tile
  (ACTION_TILE "colr_over" "(setq tn_colr_over (get_tile \"colr_over\"))(set_colr_mode)")
  (ACTION_TILE "ldrc_value" "(setv_ldrc)")
  (ACTION_TILE "txtc_value" "(setv_txtc)")
  (ACTION_TILE "ldr_slide" "(sets_ldrc)")
  (ACTION_TILE "txt_slide" "(sets_txtc)")
  (ACTION_TILE "decimal_size" "(set_decimal (get_tile\"decimal_size\"))")
  (ACTION_TILE "leroy_size" "(set_leroy (get_tile\"leroy_size\"))")
  (ACTION_TILE "add_bubble" "(set_bubl)")
  (ACTION_TILE "detail_desg" "(set_bubl)")
  (ACTION_TILE "sheet_locn" "(set_bubl)")
  (ACTION_TILE
    "Save_changes"
    "(set_bubl)(setq new_tnote_list T)(upd_tnote_dat)"
  ) ;_ end of ACTION_TILE
  (ACTION_TILE
    "Add_more"
    "(setq tn_newitem (get_tile \"new_item\"))(add_tn_item)(mode_tile \"new_item\" 2)"
  ) ;_ end of action_tile
  (ACTION_TILE
    "Repl_line"
    "(setq tn_repl_key (get_tile \"Major\"))(repl_item)"
  ) ;_ end of action_tile
  (ACTION_TILE
    "Delete_line"
    "(setq tn_del_key (get_tile \"Major\"))(del_tnlines)(set_tile\"new_item\" \"\")"
  ) ;_ end of action_tile
  (ACTION_TILE
    "Place_note"
    "(setq tn_newitem (get_tile \"new_item\"))(set_bubl)(setq tn_pl_note T tnpset_size (get_tile\"leroy_size\"))(done_dialog 1)"
  ) ;_ end of action_tile
  (ACTION_TILE "Add_cancel" "(setq tnpset_size nil)(done_dialog 0)")
  (ACTION_TILE "help_tnote" "(browser_help \"tnote\")")
  (f_tnote)
  (IF tn_wrap_len
    (PROGN
      (SET_TILE "Wrap_value" tn_wrap_len)
      (SET_TILE "Wrap_slide" tn_wrap_len)
    ) ;_ end of progn
    (PROGN
      (SET_TILE "Wrap_value" "65")
      (SET_TILE "Wrap_slide" "65")
    ) ;_ end of progn
  ) ;_ end of if
  (MODE_TILE "new_item" 2)
  (START_DIALOG)
  (UNLOAD_DIALOG tn_num)
  (IF tn_pl_note
    (place_note)
    (PRINC)
  ) ;_ end of if
  (IF old_tnoterror
    (SETQ *ERROR* old_tnoterror)
  )
  (SETQ prev_sel_key sel_key)
  (IF getstyle (getstyle ""))
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(defun set_colr_mode ()
  (IF tn_colr_over nil (SETQ tn_colr_over "0"))
  (MODE_TILE "txtc_value" (abs(1-(atoi tn_colr_over))))
  (MODE_TILE "ldrc_value" (abs(1-(atoi tn_colr_over))))
  (MODE_TILE "txt_slide" (abs(1-(atoi tn_colr_over))))
  (MODE_TILE "ldr_slide" (abs(1-(atoi tn_colr_over))))
  (IF (EQ tn_colr_over "1")
    (progn
      (SETQ tnote_cusc T)
      (SETQ tnote_ldrc (get_tile "ldrc_value"))
      (SETQ tnote_txtc (get_tile "txtc_value"))
    )
    (SETQ tnote_cusc nil)
  )
)
;;;********************************************************************
(defun setv_ldrc ()
  (SETQ tnote_ldrc (get_tile "ldrc_value"))
  (SET_TILE "ldr_slide" tnote_ldrc)
)
;;;********************************************************************
(defun setv_txtc ()
  (SETQ tnote_txtc (get_tile "txtc_value"))
  (SET_TILE "txt_slide" tnote_txtc)
)
;;;********************************************************************
(defun sets_ldrc ()
  (SETQ tnote_ldrc (get_tile "ldr_slide"))
  (SET_TILE "ldrc_value" tnote_ldrc)
)
;;;********************************************************************
(defun sets_txtc ()
  (SETQ tnote_txtc (get_tile "txt_slide"))
  (SET_TILE "txtc_value" tnote_txtc)
)
;;;********************************************************************
(DEFUN set_decimal (tn_decval / )
  (IF (EQ (SUBSTR tn_decval 1 1) ".")
    (SETQ tn_decval (STRCAT "0" tn_decval))
  )
  (IF (OR (EQ (TYPE (READ tn_decval)) 'REAL)(EQ (TYPE (READ tn_decval)) 'INT))
    (PROGN
      (SETQ dec2ler (* (ATOF tn_decval) 1000.0)
	    remcnt 1
	    tst_real dec2ler)
      (WHILE (AND (/= (REM tst_real 1) 0.0)(< remcnt 5))
	(SETQ tst_real (* 10.0 tst_real)
	      remcnt (1+ remcnt))
      )
      (SETQ tn_thts (RTOS dec2ler 2 (1- remcnt)))
      (SET_TILE "leroy_size" tn_thts)
    )
    (SET_TILE "error" "Value entered for Decimal size is invalid!")
  )
)
;;;********************************************************************
(DEFUN set_leroy (tn_lerval / )
  (IF (EQ (SUBSTR tn_lerval 1 1) ".")
    (SETQ tn_lerval (STRCAT "0" tn_lerval))
  )
  (IF (OR (EQ (TYPE (READ tn_lerval)) 'REAL)(EQ (TYPE (READ tn_lerval)) 'INT))
    (PROGN
      (SETQ tst_real (ATOF tn_lerval)
	    remcnt 4)
      (WHILE (AND (EQ (REM tst_real 1) 0.0)(> remcnt 0))
	(SETQ tst_real (/ tst_real 10.0)
	      remcnt (1- remcnt))
      )
      (SETQ ler2dec (/ (ATOF tn_lerval) 1000.0)
            tn_thts tn_lerval
	    siz_prec (+ remcnt 2))
      (SETQ dechts (RTOS ler2dec 2 remcnt))
      (SET_TILE "decimal_size" dechts)
    )
    (SET_TILE "error" "Value entered for Leroy size is invalid!")
  )
)
;;;********************************************************************
(DEFUN set_bubl	()
  (SETQ tn_wrap_len (GET_TILE "Wrap_value"))
  (SETQ tn_add_bubble (GET_TILE "add_bubble"))
  (SETQ	tn_detail_desg
;;;	 (IF (EQ tn_add_bubble "1")
	   (GET_TILE "detail_desg")
;;;	   ""
;;;	 ) ;_ end of IF
  ) ;_ end of SETQ
  (SETQ	tn_sheet_locn
;;;	 (IF (EQ tn_add_bubble "1")
	   (GET_TILE "sheet_locn")
;;;	   ""
;;;	 ) ;_ end of IF
  ) ;_ end of SETQ
  (IF (MEMBER (ASSOC tn_newitem tndat_lst) tndat_lst)
    (SETQ tndat_lst
	   (SUBST
	     (CONS tn_newitem (LIST tn_detail_desg tn_sheet_locn tn_wrap_len))
	     (ASSOC tn_newitem tndat_lst)
	     tndat_lst
	   ) ;_ end of SUBST
    ) ;_ end of SETQ
  ) ;_ end of IF
  (MODE_TILE "detail_desg" (ABS (1- (ATOI tn_add_bubble))))
  (MODE_TILE "sheet_locn" (ABS (1- (ATOI tn_add_bubble))))
) ;_ end of defun
;;;********************************************************************
(DEFUN f_tnote (/)
  (set_tnote_list)
  (chk_tnlst)
  (START_LIST "Major" 3)
  (MAPCAR 'ADD_LIST tnote_list)
  (END_LIST)
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN srch_tnlist (/)
  (SETQ srch_result NIL)
  (set_tile "error" "")
  (foreach n tnote_list
    (if (wcmatch (STRCASE n) (STRCASE tn_srch_str))
      (SETQ srch_result (APPEND srch_result (LIST n)))
    )
  )
  (IF srch_result
    (PROGN
      (setq sel_key nil)
      (NEW_DIALOG "srchres" tn_num)
;;;      (mode_tile "dtl_desg" 1)
;;;      (mode_tile "sht_locn" 1)
      (action_tile "Results" "(setq sel_key(get_tile\"Results\"))(setq sel_str (nth (read sel_key) srch_result))(set_srchbubl)(if(eq $reason 4)(done_dialog 1))")
      (action_tile "Filter" "(setq fltr_str (strcat \"*\"(get_tile \"filter_item\")\"*\"))(fltr_tnlist)")
      (action_tile "ok" "(done_dialog 1)")
      (action_tile "cancel" "(done_dialog 0)")
      (START_LIST "Results" 3)
      (MAPCAR 'ADD_LIST srch_result)
      (END_LIST)
      (if
	(eq (START_DIALOG) 1)
        (if sel_key
	  (progn
            (setq sel_key (itoa (1- (length (member (nth (read sel_key) srch_result) (reverse tnote_list))))))
            (set_tile "Major" sel_key)
            (mode_tile "Major" 2)
            (set_tnote_ebox)
            (setq tn_newitem (get_tile"new_item"))
            (set_wrap)
            (set_pview)
	  )
	  (set_tile "error" "Nothing selected from search results")
        )
        (set_tile "error" "Search cancelled")
      )
    )
    (set_tile "error" "Search string did not match any note")
  )
  (PRINC)
)
;;;********************************************************************
(DEFUN fltr_tnlist (/)
  (SETQ fltr_result NIL)
  (set_tile "error" "")
  (foreach n srch_result
    (if (wcmatch (STRCASE n) (STRCASE fltr_str))
      (SETQ fltr_result (APPEND fltr_result (LIST n)))
    )
  )
  (if fltr_result
    (progn
      (setq srch_result fltr_result)
      (START_LIST "Results" 3)
      (MAPCAR 'ADD_LIST fltr_result)
      (END_LIST)
    )
    (SET_TILE "error" "No matches found for filter text!")
  )
)
;;;********************************************************************
(DEFUN set_srchbubl (/)
  (SET_TILE "filter_item" sel_str)
  (foreach n tndat_lst
    (if (eq (nth 0 n) sel_str)
      (PROGN
        (SET_TILE "dtl_desg" (nth 1 n))
        (SET_TILE "sht_locn" (nth 2 n))
      ) ;_ end of progn
    )
  )
)
;;;********************************************************************
(DEFUN tn_set_caps (/)
  (IF (EQ tn_fcaps "1")
    (IF tn_newitem
      (SETQ tn_newitem (STRCASE tn_newitem))
    )
  )
) ;_ end of defun
;;;********************************************************************
(DEFUN pview (/)
  (IF (EQ (GET_TILE "force_caps") "1")
    (progn
      (setq tn_newitem (strcase tn_newitem))
      (foreach n pview_lst
        (setq pview_lst (subst (strcase n) n pview_lst))
      )
      (SET_TILE "new_item" tn_newitem)
    )
  )
  (START_LIST "note_view")
  (MAPCAR 'ADD_LIST pview_lst)
  (END_LIST)
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN get_dat_file ()
  (if (not (findfile (STRCAT (GETVAR "dwgprefix") "tnote.dat")))
    (progn
      (setq tmp_datf (open (STRCAT (GETVAR "dwgprefix") "tnote.dat") "w"))
      (close tmp_datf)
    )
  )
  (IF
    (SETQ tn_file
	   (GETFILED "Open Typical Notes Data File"
		     (STRCAT (GETVAR "dwgprefix") "tnote.dat")
		     "dat"
		     8
	   ) ;_ end of getfiled
    ) ;_ end of setq
     (PROGN
       (SETQ tnote_list
	      nil
	     tndat_lst nil
       ) ;_ end of setq
;;;       (SETQ tn_file (FINDFILE "tnote.dat"))
       (SET_TILE "tnote_path" tn_file)
       (IF (FINDFILE tn_file)
	 (PROGN
         (SETQ tn_dat (OPEN (FINDFILE tn_file) "r"))
       (WHILE
	 (SETQ str (READ-LINE tn_dat))
	  (IF (AND (EQ (SUBSTR str 1 1) (CHR 40))
					; Line begins with a parenthesis, and
		   (EQ (SUBSTR str (STRLEN str) 1) (CHR 41))
					; Line ends with a parenthesis
	      ) ;_ end of and
	    (SETQ tndat_lst (APPEND tndat_lst (LIST (READ str))))
					; Then strip off string quotes and add/create tndat_lst
	    (SETQ
	      tndat_lst	(APPEND tndat_lst (LIST (LIST str "" "" "65" (IF do_cmud "100" "125"))))
	    ) ;_ end of SETQ
					; Else add/create tndat_lst using the string
	  ) ;_ end of if
       ) ;_ end of while
       (CLOSE tn_dat)
       (FOREACH	n tndat_lst		; tndat_lst=Data list including specified detail bubble text
	 (IF tnote_list
	   (SETQ tnote_list (APPEND tnote_list (LIST (CAR n))))
					; Extract note string from list
	   (SETQ tnote_list (LIST (CAR n)))
	 ) ;_ end of if
       ) ;_ end of foreach
	 )
       )
       (IF tnote_list
         (IF (SETQ tn_lst (ACAD_STRLSORT tnote_list))
					; Finally, sort the note list
	   (SETQ tnote_list tn_lst)
	   (PRINC "\nNot enough memory to sort tnote group list. ")
         ) ;_ end of if
	 (set_tile "error" "*** NOTICE *** DAT file contains no notes! Add notes or open another file.")
       )
       (chk_tnlst)
       (START_LIST "Major" 3)
       (MAPCAR 'ADD_LIST tnote_list)
       (END_LIST)
     ) ;_ end of progn
  ) ;_ end of if
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN set_tnote_list (/)
  (IF tnote_list
    (PROGN
      (IF tn_file
        (SET_TILE "tnote_path" tn_file)
      )
    )
    (PROGN
      (SETQ tnote_list
	     nil
	    tndat_lst nil
            tndat_ndx nil
      ) ;_ end of setq
      (if (not (findfile "tnote.dat"))
        (progn
          (setq tmp_datf (open (STRCAT (GETVAR "dwgprefix") "tnote.dat") "w"))
          (close tmp_datf)
        )
      )
      (SETQ tn_file (FINDFILE "tnote.dat"))
      (SET_TILE "tnote_path" tn_file)
      (SETQ tn_dat (OPEN tn_file "r"))
      (WHILE
	(SETQ str (READ-LINE tn_dat))
	 (IF (AND (EQ (SUBSTR str 1 1) (CHR 40))
					; Line begins with a parenthesis, and
		  (EQ (SUBSTR str (STRLEN str) 1) (CHR 41))
					; Line ends with a parenthesis
	     ) ;_ end of and
	   (SETQ tndat_lst (APPEND tndat_lst (LIST (READ str))))
					; Then strip off string quotes and add/create tndat_lst
	   (SETQ
	     tndat_lst (APPEND tndat_lst (LIST (LIST str "" "" "65" (IF do_cmud "100" "125"))))
	   ) ;_ end of SETQ
					; Else add/create tndat_lst using the string
	 ) ;_ end of if
      ) ;_ end of while
      (CLOSE tn_dat)
      (tnote_sorter)
    ) ;_ end of PROGN
  ) ;_ end of IF
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN tnote_sorter ()
      (SETQ ndx_cnt 0
	    tndat_ndx nil
	    tnote_list nil
      )
      (FOREACH n tndat_lst		; tndat_lst=Data list including specified detail bubble text
	(IF tndat_ndx
	  (SETQ tndat_ndx (APPEND tndat_ndx (LIST (CONS (CAR n) ndx_cnt))))
	  (SETQ tndat_ndx (LIST (CONS (CAR n) ndx_cnt)))
	)
	(SETQ ndx_cnt (1+ ndx_cnt))
	(IF (AND tnote_list (NOT (MEMBER (CAR n) tnote_list)))
	  (SETQ tnote_list (APPEND tnote_list (LIST (CAR n))))
					; Extract note string from list
	  (IF tnote_list
	    NIL
	    (SETQ tnote_list (LIST (CAR n)))
	  )
	) ;_ end of if
      ) ;_ end of foreach
      (IF tnote_list
	(IF (SETQ tn_lst (ACAD_STRLSORT tnote_list))
					; Finally, sort the note list
	  (PROGN
	    (SETQ tnote_list tn_lst)
	    (SETQ tndat_tas nil)
	    (foreach n tnote_list
	      (IF tndat_tas
		(SETQ tndat_tas (APPEND tndat_tas (LIST (NTH (CDR (ASSOC n tndat_ndx)) tndat_lst))))
		(SETQ tndat_tas (LIST (NTH (CDR (ASSOC n tndat_ndx)) tndat_lst)))
              )
	    )
	    (SETQ tndat_lst tndat_tas)
	  )
	    (PRINC "\nNot enough memory to sort tnote group list. ")
	) ;_ end of if
	(SET_TILE
	  "error"
	  "*** NOTICE *** DAT file contains no notes! Add notes or open another file."
	) ;_ end of set_tile
      ) ;_ end of IF
)
;;;********************************************************************
(DEFUN set_wrap	()
  (IF
    (AND
      (ASSOC (NTH (ATOI sel_key) tnote_list) tndat_lst)
      (/= (NTH 3 (ASSOC (NTH (ATOI sel_key) tnote_list) tndat_lst))
	  ""
      ) ;_ end of /=
      (EQ (TYPE
	    (READ
	      (NTH 3 (ASSOC (NTH (ATOI sel_key) tnote_list) tndat_lst))
	    ) ;_ end of READ
	  ) ;_ end of TYPE
	  'INT
      ) ;_ end of EQ
    ) ;_ end of AND
     (PROGN
       (SETQ tn_wrap_len
	      (NTH 3
		   (ASSOC (NTH (ATOI sel_key) tnote_list) tndat_lst)
	      ) ;_ end of NTH
       ) ;_ end of SETQ
       (SET_TILE "Wrap_value" tn_wrap_len)
     ) ;_ end of PROGN
  ) ;_ end of IF
) ;_ end of DEFUN
;;;********************************************************************
(DEFUN set_tnote_ebox (/)
  (SETQ sel_key (GET_TILE "Major"))
  (SETQ note_txt (NTH (ATOI sel_key) tnote_list))
  (SET_TILE "new_item" note_txt)
  (res_tn_thts note_txt)
  (IF (MEMBER note_txt tndat_lst);only true if note is a string and not a list in tndat_lst
    (PROGN
      (SET_TILE "add_bubble" "0")
      (SET_TILE "detail_desg" "")
      (SET_TILE "sheet_locn" "")
      (MODE_TILE "detail_desg" 1)
      (MODE_TILE "sheet_locn" 1)
    ) ;_ end of progn
    (PROGN
      (SETQ note_ctr 0
	    not_yet T
      ) ;_ end of setq
      (SETQ note_str (NTH (ATOI sel_key) tnote_list))
      (WHILE (AND (< note_ctr (LENGTH tndat_lst)) not_yet)
	(COND ((EQ (TYPE (NTH note_ctr tndat_lst)) 'LIST)
	       (IF (EQ (CAR (NTH note_ctr tndat_lst)) note_str)
		 (SETQ not_yet nil)
	       ) ;_ end of if
	      )
	) ;_ end of cond
	(SETQ note_ctr (1+ note_ctr))
      ) ;_ end of while
      (IF (EQ (TYPE (NTH (1- note_ctr) tndat_lst)) 'LIST)
	(PROGN
	  (SET_TILE "detail_desg"
		    (NTH 1 (NTH (1- note_ctr) tndat_lst))
	  ) ;_ end of set_tile
	  (SET_TILE "sheet_locn"
		    (NTH 2 (NTH (1- note_ctr) tndat_lst))
	  ) ;_ end of set_tile
	  (IF (AND
		(/= (NTH 3 (NTH (1- note_ctr) tndat_lst)) "")
		(EQ (TYPE (READ (NTH 3 (NTH (1- note_ctr) tndat_lst))))
		    'INT
		) ;_ end of EQ
	      ) ;_ end of AND
	    (SET_TILE "Wrap_value"
		      (NTH 3 (NTH (1- note_ctr) tndat_lst))
	    ) ;_ end of set_tile
	  ) ;_ end of IF
	  (IF (EQ (LENGTH (NTH (1- note_ctr) tndat_lst)) 5)
	    (PROGN
	      (SET_TILE "leroy_size" (NTH 4 (NTH (1- note_ctr) tndat_lst)))
	      (set_leroy (NTH 4 (NTH (1- note_ctr) tndat_lst)))
	    )
	  )
	  (IF (AND (EQ (GET_TILE "detail_desg") "")
		   (EQ (GET_TILE "sheet_locn") "")
	      ) ;_ end of and
	    (PROGN
	      (SET_TILE "add_bubble" "0")
	      (MODE_TILE "detail_desg" 1)
	      (MODE_TILE "sheet_locn" 1)
	    ) ;_ end of progn
	    (PROGN
	      (SET_TILE "add_bubble" "1")
	      (MODE_TILE "detail_desg" 0)
	      (MODE_TILE "sheet_locn" 0)
	    ) ;_ end of progn
	  ) ;_ end of if
	) ;_ end of progn
      ) ;_ end of if
    ) ;_ end of progn
  ) ;_ end of if
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN repl_item (/)
  (IF (EQ (TYPE (READ tn_repl_key)) 'INT)
    (PROGN
      (SETQ exst_str (NTH (ATOI tn_repl_key) tnote_list)
	    repl_str (GET_TILE "new_item")
	    rslen    (STRLEN repl_str)
	    chrcnt   1
      ) ;_ end of setq
      (SETQ new_tnote_list (SUBST repl_str exst_str tnote_list)
	    tnote_list	   new_tnote_list
      ) ;_ end of setq
;;;      (COND
;;;	((MEMBER exst_str tndat_lst)	; No bubble associated yet
;;;	 (COND ((EQ (GET_TILE "add_bubble") "0")
;;;					; No bubble associated this instance - No change
;;;		(SETQ tndat_lst
;;;		       (SUBST repl_str
;;;			      exst_str
;;;			      tndat_lst
;;;		       ) ;_ end of subst
;;;		) ;_ end of setq
;;;	       )
;;;	       ((EQ (GET_TILE "add_bubble") "1")
;;;					; Bubble associated this instance - add bubble data
		(SETQ tndat_lst
		       (SUBST
			 (CONS
			   repl_str
			   (LIST (GET_TILE "detail_desg")
				 (GET_TILE "sheet_locn")
				 (GET_TILE "Wrap_value")
				 (GET_TILE "leroy_size")
			   ) ;_ end of LIST
			 ) ;_ end of cons
			 exst_str
			 tndat_lst
		       ) ;_ end of subst
		) ;_ end of setq
;;;	       )
;;;	 ) ;_ end of cond
;;;	)
;;;	((ASSOC exst_str tndat_lst)
;;;	 (COND ((EQ (GET_TILE "add_bubble") "0")
;;;		(SETQ tndat_lst
;;;		       (SUBST (CONS repl_str (CDR (ASSOC exst_str tndat_lst)))
;;;			      (ASSOC exst_str tndat_lst)
;;;			      tndat_lst
;;;		       ) ;_ end of subst
;;;		) ;_ end of setq
;;;	       )
;;;	       ((EQ (GET_TILE "add_bubble") "1")
;;;		(SETQ tndat_lst
;;;		       (SUBST
;;;			 (CONS
;;;			   repl_str
;;;			   (LIST (GET_TILE "detail_desg")
;;;				 (GET_TILE "sheet_locn")
;;;				 (GET_TILE "Wrap_value")
;;;				 (GET_TILE "leroy_size")
;;;			   ) ;_ end of LIST
;;;			 ) ;_ end of cons
;;;			 (ASSOC exst_str tndat_lst)
;;;			 tndat_lst
;;;		       ) ;_ end of subst
;;;		) ;_ end of setq
;;;	       )
;;;	 ) ;_ end of cond
;;;	)
;;;      ) ;_ end of cond
      (SET_TILE "new_item" "")
      (MODE_TILE "new_item" 2)
      (START_LIST "Major" 1 (ATOI tn_repl_key))
      (ADD_LIST repl_str)
      (END_LIST)
      (SET_TILE "Major" tn_repl_key)
      (SET_TILE "new_item" (NTH (ATOI tn_repl_key) tnote_list))
      (MODE_TILE "new_item" 3)
      (upd_tnote_dat)
    ) ;_ end of progn
  ) ;_ end of if
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN upd_tnote_dat (/)
  (IF (AND new_tnote_list (/= new_tnote_list prev_tnlst))
    (PROGN
      (IF tn_file
	NIL
	(SETQ tn_file (FINDFILE "tnote.dat"))
      ) ;_ end of IF
      (SET_TILE "tnote_path" tn_file)
      (SETQ tn_dat (OPEN tn_file "w"))
      (IF tn_dat
	(PROGN
	  (FOREACH n tndat_lst
	    (COND ((EQ (TYPE n) 'LIST)
		   (SETQ tx_str	(NTH 0 n)
			 rslen	(STRLEN tx_str)
			 chrcnt	1
		   ) ;_ end of setq
		   (IF (WCMATCH tx_str "*\"*")
		     (WHILE (<= chrcnt rslen)
		       (IF (EQ (SUBSTR tx_str chrcnt 1) "\"")
			 (PROGN
			   (SETQ tx_str	(STRCAT
					  (SUBSTR tx_str 1 (1- chrcnt))
					  (CHR 92)
					  (CHR 34)
					  (SUBSTR tx_str (1+ chrcnt))
					) ;_ end of strcat
				 rslen	(STRLEN tx_str)
				 chrcnt	(STRLEN
					  (STRCAT (SUBSTR tx_str 1 (1- chrcnt))
						  (CHR 92)
						  (CHR 34)
					  ) ;_ end of strcat
					) ;_ end of strlen
			   ) ;_ end of setq
			 ) ;_ end of progn
		       ) ;_ end of if
		       (SETQ chrcnt (1+ chrcnt))
		     ) ;_ end of while
		   ) ;_ end of if
		   (SETQ tn_item (STRCAT (CHR 40)
					 "\""
					 tx_str
					 "\" \""
					 (NTH 1 n)
					 "\" \""
					 (NTH 2 n)
					 "\" \""
					 (NTH 3 n)
					 (IF (EQ (LENGTH n) 5)
					   (STRCAT
					     "\" \""
					     (NTH 4 n)
					     "\""
					     (CHR 41)
					   ) ;_ end of STRCAT
					   (STRCAT
					     "\" \""
					     (IF do_cmud
					       "100"
					       "125"
					     ) ;_ end of IF
					     "\""
					     (CHR 41)
					   ) ;_ end of STRCAT
					 ) ;_ end of IF
				 ) ;_ end of strcat
		   ) ;_ end of setq
		   (WRITE-LINE tn_item tn_dat)
		  )
		  ((EQ (TYPE n) 'STR)
		   (WRITE-LINE n tn_dat)
		  )
	    ) ;_ end of cond
	  ) ;_ end of foreach
	  (IF (AND tn_dat tndat_lst)
	    (SET_TILE "error" (STRCAT "Saved changes to " tn_file))
	  ) ;_ end of IF
	) ;_ end of PROGN
        (PROGN
          (SET_TILE "error" "Unable to open .dat file!")
        ) ;_ end of PROGN
      ) ;_ end of IF
      (SETQ new_tnote_list NIL)
      (CLOSE tn_dat)
    ) ;_ end of progn
    (PROGN
      (SET_TILE "error" "Nothing to Save!")
    ) ;_ end of PROGN
  ) ;_ end of if
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN add_tn_item	(/)
  (IF (EQ tn_newitem "")
    nil
    (PROGN
      (SETQ new_tnote_list tnote_list)
      (SETQ tnote_list (APPEND tnote_list (LIST tn_newitem)))
      (chk_tnlst)
      (START_LIST "Major" 3)
      (MAPCAR 'ADD_LIST tnote_list)
      (END_LIST)
      (IF tndat_lst
	(COND
	  ((EQ (GET_TILE "add_bubble") "0")
	   (SETQ
	     tndat_lst
	      (APPEND
		tndat_lst
		(LIST
		  (LIST tn_newitem "" "" (GET_TILE "Wrap_value") (GET_TILE "leroy_size"))
		) ;_ end of LIST
	      ) ;_ end of APPEND
	   ) ;_ end of setq
	  )
	  ((EQ (GET_TILE "add_bubble") "1")
	   (SETQ
	     tndat_lst (APPEND tndat_lst
			       (LIST (LIST tn_newitem
					   (GET_TILE "detail_desg")
					   (GET_TILE "sheet_locn")
					   (GET_TILE "Wrap_value")
					   (GET_TILE "leroy_size")
				     ) ;_ end of list
			       ) ;_ end of list
		       ) ;_ end of append
	   ) ;_ end of setq
	  )
	) ;_ end of cond
	(COND ((EQ (GET_TILE "add_bubble") "0")
	       (SETQ tndat_lst
		      (LIST (LIST tn_newitem "" "" (GET_TILE "Wrap_value"))
		      ) ;_ end of LIST
	       ) ;_ end of SETQ
	      )
	      ((EQ (GET_TILE "add_bubble") "1")
	       (SETQ tndat_lst (LIST (LIST tn_newitem
					   (GET_TILE "detail_desg")
					   (GET_TILE "sheet_locn")
					   (GET_TILE "Wrap_value")
					   (GET_TILE "leroy_size")
				     ) ;_ end of list
			       ) ;_ end of list
	       ) ;_ end of setq
	      )
	) ;_ end of cond
      ) ;_ end of if
      (tnote_sorter)
      (upd_tnote_dat)
      (SETQ tn_newitem nil)
    ) ;_ end of progn
  ) ;_ end of if
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN place_note
       (/ nxt_char chr_indx wrap_int var_indx fst_break lst_break)
  (upd_tnote_dat)
  (SETQ do_tnote T)
  (SETQ	char_index
		   1
	tmp1_index 1
  ) ;_ end of setq
  (cond
    ((eq tn_space "tn_msp")
     (command ".mspace")
     )
    ((eq tn_space "tn_psp")
     (command ".pspace")
     )
  )
  (IF (= tn_newitem "")
    (PRINC)
    (PROGN
      (upd_tn_thts tn_newitem tnpset_size)
      (SETQ note_txt tn_newitem)
      (IF tn_wrap_len
	(PROGN
	  (SETQ	chr_indx 1
		var_indx 1
		wrap_int (ATOI tn_wrap_len)
	  ) ;_ end of setq
	  (SETQ nxt_char (SUBSTR note_txt chr_indx 1))
	  (WHILE (AND (NOT note_done) (NOT (EQ "" note_txt)))
	    (IF	(EQ nxt_char " ")	;if breakpoint
	      (PROGN
		(IF lst_break
		  (SETQ fst_break lst_break)
		) ;_ end of if
		(SETQ lst_break chr_indx)
	      ) ;_ end of PROGN
	    ) ;_ end of if
	    (IF	(EQ nxt_char "")	;if endpoint
	      (PROGN
		(IF lst_break
		  (SETQ fst_break lst_break)
		) ;_ end of if
		(SETQ lst_break	chr_indx
		      done_note	T
		) ;_ end of setq
	      ) ;_ end of PROGN
	    ) ;_ end of if
	    (COND
	      ((> lst_break wrap_int)
	       (SET (READ (STRCAT "typ_t" (ITOA var_indx)))
		    (SUBSTR note_txt
			    1
			    (IF	fst_break
			      (1- fst_break)
			      (1- lst_break)
			    ) ;_ end of if
		    ) ;_ end of substr
	       ) ;_ end of set
	       (SETQ note_txt  (SUBSTR note_txt
				       (IF fst_break
					 (1+ fst_break)
					 (1+ lst_break)
				       ) ;_ end of if
			       ) ;_ end of substr
		     chr_indx  1
		     var_indx  (1+ var_indx)
		     fst_break nil
		     lst_break nil
		     nxt_char  (SUBSTR note_txt 1 1)
	       ) ;_ end of setq
	      )
	      ((EQ lst_break wrap_int)	;if 2nd break = wrap length
	       (SET (READ (STRCAT "typ_t" (ITOA var_indx)))
		    (SUBSTR note_txt 1 (1- lst_break))
	       ) ;_ end of set
	       (IF (> (STRLEN note_txt) wrap_int)
		 (SETQ note_txt	 (SUBSTR note_txt (1+ lst_break))
		       chr_indx	 1
		       var_indx	 (1+ var_indx)
		       fst_break nil
		       lst_break nil
		       nxt_char	 (SUBSTR note_txt 1 1)
		 ) ;_ end of setq
		 (SETQ nxt_char	""
		       note_done T
		 ) ;_ end of setq
	       ) ;_ end of if
	      )
	      ((<= (STRLEN note_txt) wrap_int)
	       (SET (READ (STRCAT "typ_t" (ITOA var_indx)))
		    note_txt
	       ) ;_ end of set
	       (SETQ nxt_char ""
		     note_done T
	       ) ;_ end of setq
	      )
	    ) ;_ end of COND
	    (SETQ chr_indx (1+ chr_indx)
		  nxt_char (SUBSTR note_txt chr_indx 1)
	    ) ;_ end of setq
	  ) ;_ end of WHILE
	  (IF note_done
	    (SETQ note_done nil)
	    (PROGN
	      (SET (READ (STRCAT "typ_t" (ITOA var_indx)))
		   note_txt
	      ) ;_ end of set
	    ) ;_ end of PROGN
	  ) ;_ end of IF
	) ;_ end of PROGN
	(SETQ typ_t1 note_txt)		;Do this if NO WRAP
      ) ;_ end of IF
      (c:mlt)
      (SETQ
	typ_t1 nil
	typ_t2 nil
	typ_t3 nil
	typ_t4 nil
	typ_t5 nil
	typ_t6 nil
	typ_t7 nil
	typ_t8 nil
	typ_t9 nil
	typ_t10	nil
	fst_break nil
	lst_break nil
	do_tnote nil
      ) ;_ end of setq
    ) ;_ end of PROGN
  ) ;_ end of IF
  (PRINC)
) ;_ end of DEFUN
;;;********************************************************************
(DEFUN set_pview
       (/ nxt_char chr_indx wrap_int var_indx fst_break lst_break)
  (SETQ	char_index
		   1
	tmp1_index 1
  ) ;_ end of setq
  (IF (= tn_newitem "")
    (PRINC)
    (PROGN
      (SETQ note_txt tn_newitem)
      (IF tn_wrap_len
	(PROGN
	  (SETQ	chr_indx 1
		var_indx 1
		wrap_int (ATOI tn_wrap_len)
	  ) ;_ end of setq
	  (SETQ nxt_char (SUBSTR note_txt chr_indx 1))
	  (WHILE (AND (NOT note_done) (NOT (EQ "" note_txt)))
	    (IF	(EQ nxt_char " ")	;if breakpoint
	      (PROGN
		(IF lst_break
		  (SETQ fst_break lst_break)
		) ;_ end of if
		(SETQ lst_break chr_indx)
	      ) ;_ end of PROGN
	    ) ;_ end of if
	    (IF	(EQ nxt_char "")	;if endpoint
	      (PROGN
		(IF lst_break
		  (SETQ fst_break lst_break)
		) ;_ end of if
		(SETQ lst_break	chr_indx
		      done_note	T
		) ;_ end of setq
	      ) ;_ end of PROGN
	    ) ;_ end of if
	    (COND
	      ((> lst_break wrap_int)
	       (SET (READ (STRCAT "typ_t" (ITOA var_indx)))
		    (IF	fst_break
		      (SUBSTR note_txt 1 (1- fst_break))
		      (SUBSTR note_txt 1 (1- lst_break))
		    ) ;_ end of if
	       ) ;_ end of set
	       (SETQ note_txt  (IF fst_break
				 (SUBSTR note_txt (1+ fst_break))
				 (SUBSTR note_txt (1+ lst_break))
			       ) ;_ end of if
		     chr_indx  1
		     var_indx  (1+ var_indx)
		     fst_break nil
		     lst_break nil
		     nxt_char  (SUBSTR note_txt 1 1)
	       ) ;_ end of setq
	      )
	      ((EQ lst_break wrap_int)	;if 2nd break = wrap length
	       (SET (READ (STRCAT "typ_t" (ITOA var_indx)))
		    (SUBSTR note_txt 1 (1- lst_break))
	       ) ;_ end of set
	       (IF (> (STRLEN note_txt) wrap_int)
		 (SETQ note_txt	 (SUBSTR note_txt (1+ lst_break))
		       chr_indx	 1
		       var_indx	 (1+ var_indx)
		       fst_break nil
		       lst_break nil
		       nxt_char	 (SUBSTR note_txt 1 1)
		 ) ;_ end of setq
		 (SETQ nxt_char	""
		       note_done T
		 ) ;_ end of setq
	       ) ;_ end of if
	      )
	      ((<= (STRLEN note_txt) wrap_int)
	       (SET (READ (STRCAT "typ_t" (ITOA var_indx)))
		    note_txt
	       ) ;_ end of set
	       (SETQ nxt_char ""
		     note_done T
	       ) ;_ end of setq
	      )
	    ) ;_ end of COND
	    (SETQ chr_indx (1+ chr_indx)
		  nxt_char (SUBSTR note_txt chr_indx 1)
	    ) ;_ end of setq
	  ) ;_ end of WHILE
	  (IF note_done
	    (SETQ note_done nil)
	    (PROGN
	      (SET (READ (STRCAT "typ_t" (ITOA var_indx)))
		   note_txt
	      ) ;_ end of set
	    ) ;_ end of PROGN
	  ) ;_ end of IF
	) ;_ end of PROGN
	(SETQ typ_t1 note_txt)		;Do this if NO WRAP
      ) ;_ end of IF
      (PRINC fst_break)
      (PRINC lst_break)
      (IF typ_t1
	(PROGN
	  (SETQ pview_lst (LIST typ_t1))
	  (IF typ_t2
	    (PROGN
	      (SETQ pview_lst (APPEND pview_lst (LIST typ_t2)))
	      (IF typ_t3
		(PROGN
		  (SETQ pview_lst (APPEND pview_lst (LIST typ_t3)))
		  (IF typ_t4
		    (PROGN
		      (SETQ pview_lst (APPEND pview_lst (LIST typ_t4)))
		      (IF typ_t5
			(PROGN
			  (SETQ
			    pview_lst (APPEND pview_lst (LIST typ_t5))
			  ) ;_ end of setq
			  (IF typ_t6
			    (PROGN
			      (SETQ pview_lst (APPEND pview_lst
						      (LIST typ_t6)
					      ) ;_ end of append
			      ) ;_ end of setq
			      (IF typ_t7
				(PROGN
				  (SETQ
				    pview_lst (APPEND pview_lst
						      (LIST typ_t7)
					      ) ;_ end of append
				  ) ;_ end of setq
				  (IF typ_t8
				    (PROGN
				      (SETQ pview_lst
					     (APPEND pview_lst
						     (LIST typ_t8)
					     ) ;_ end of append
				      ) ;_ end of setq
				      (IF typ_t9
					(PROGN
					  (SETQ
					    pview_lst (APPEND
							pview_lst
							(LIST typ_t9)
						      ) ;_ end of append
					  ) ;_ end of setq
					  (IF typ_t10
					    (PROGN
					      (SETQ pview_lst
						     (APPEND
						       pview_lst
						       (LIST typ_t10
						       ) ;_ end of list
						     ) ;_ end of append
					      ) ;_ end of setq
					    ) ;_ end of progn
					    (PRINC)
					  ) ;_ end of if
					) ;_ end of progn
					(PRINC)
				      ) ;_ end of if
				    ) ;_ end of progn
				    (PRINC)
				  ) ;_ end of if
				) ;_ end of progn
				(PRINC)
			      ) ;_ end of if
			    ) ;_ end of progn
			    (PRINC)
			  ) ;_ end of if
			) ;_ end of progn
			(PRINC)
		      ) ;_ end of if
		    ) ;_ end of progn
		    (PRINC)
		  ) ;_ end of if
		) ;_ end of progn
		(PRINC)
	      ) ;_ end of if
	    ) ;_ end of progn
	    (PRINC)
	  ) ;_ end of if
	) ;_ end of progn
	(PRINC)
      ) ;_ end of if
      (pview)
      (SETQ
	typ_t1 nil
	typ_t2 nil
	typ_t3 nil
	typ_t4 nil
	typ_t5 nil
	typ_t6 nil
	typ_t7 nil
	typ_t8 nil
	typ_t9 nil
	typ_t10	nil
	fst_break nil
	lst_break nil
      ) ;_ end of setq
      (PRINC
	"\010\010\010\010\010\010      \010\010\010\010\010\010"
      ) ;_ end of princ
    ) ;_ end of PROGN
  ) ;_ end of IF
  (SET_TILE "error" "")
  (PRINC)
) ;_ end of DEFUN
;;;********************************************************************
(DEFUN intchk (ivar /)
  (IF (ATOI ivar)
    nil
    (SETQ ivar "0")
  ) ;_ end of if
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN chk_tnlst ()
  (setq tmptn_lst nil)
  (IF tnote_list
    (PROGN
      (FOREACH n tnote_list
        (IF (AND tmptn_lst n)
          (SETQ tmptn_lst (APPEND tmptn_lst (LIST n)))
          (IF n
            (SETQ tmptn_lst (LIST n))
          )
        )
      )
      (SETQ tmptn_lst (ACAD_STRLSORT tmptn_lst))
      (SETQ tnote_list tmptn_lst)
      (SETQ prev_tnlst tnote_lst)
    )
  )
)
;;;********************************************************************
(DEFUN upd_tn_thts (note_str size / )
      (IF (SETQ curnote_lst (ASSOC note_str tndat_lst))
	(PROGN
	  (COND
	    ((AND (EQ (LENGTH curnote_lst) 5)(/= (NTH 4 curnote_lst) size))
	      (SETQ tndat_lst
	        (SUBST (REVERSE (CONS size (CDR (REVERSE curnote_lst))))
		       curnote_lst
		       tndat_lst
		)
	      ))
	    ((EQ (LENGTH curnote_lst) 4)
	      (SETQ tndat_lst
	        (SUBST (REVERSE (CONS size (REVERSE curnote_lst)))
		       curnote_lst
		       tndat_lst
		)
	      ))
	  )
	)
      )
)
;;;********************************************************************
(DEFUN res_tn_thts (note_str / )
  (IF (SETQ curnote_lst (ASSOC note_str tndat_lst))
    (IF (EQ (LENGTH curnote_lst) 5)
      (PROGN
        (SET_TILE "leroy_size" (NTH 4 curnote_lst))
	(set_leroy (NTH 4 curnote_lst))
      )
    )
  )
)
;;;********************************************************************
(DEFUN del_tnlines ()
  (SETQ del_note (NTH (ATOI tn_del_key) tnote_list))
  (SETQ tnote_list (SUBST nil del_note tnote_list))
  (chk_tnlst)
  (SETQ new_tnote_list tnote_list)
  (SETQ del_dat (ASSOC del_note tndat_lst))
  (SETQ tndat_lst (SUBST nil del_dat tndat_lst))
  (SETQ tmptn_lst NIL)
  (FOREACH n tndat_lst
    (IF (AND tmptn_lst n)
      (SETQ tmptn_lst (APPEND tmptn_lst (LIST n)))
      (IF n
        (SETQ tmptn_lst (LIST n))
      )
    )
  )
  (SETQ tndat_lst tmptn_lst)
;;;  (SETQ	del_ndx_lst
;;;	 nil
;;;	cur_list nil
;;;  ) ;_ end of setq
;;;  (SETQ new_tnote_list nil)
;;;  (SETQ count 1)
;;;  (WHILE (<= count (STRLEN tn_del_key))
;;;    (WHILE (AND	(EQ (SUBSTR tn_del_key count 1) " ")
;;;		(NOT (> count (STRLEN tn_del_key)))
;;;	   ) ;_ end of and
;;;      (SETQ count (1+ count))
;;;    ) ;_ end of while
;;;    (SETQ strt_cnt count
;;;	  end_cnt 0
;;;    ) ;_ end of setq
;;;    (WHILE (AND	(NOT (EQ (SUBSTR tn_del_key count 1) " "))
;;;		(NOT (> count (STRLEN tn_del_key)))
;;;	   ) ;_ end of and
;;;      (SETQ count   (1+ count)
;;;	    end_cnt (1+ end_cnt)
;;;      ) ;_ end of setq
;;;    ) ;_ end of while
;;;    (IF	(<= strt_cnt (STRLEN tn_del_key))
;;;      (SETQ del_ndx_lst
;;;	     (IF del_ndx_lst
;;;	       (APPEND del_ndx_lst
;;;		       (LIST (ATOI (SUBSTR tn_del_key strt_cnt end_cnt)))
;;;	       ) ;_ end of append
;;;	       (LIST (ATOI (SUBSTR tn_del_key strt_cnt end_cnt)))
;;;	     ) ;_ end of if
;;;      ) ;_ end of setq
;;;    ) ;_ end of if
;;;  ) ;_ end of while
;;;  (SETQ cur_list tnote_list)
;;;  (FOREACH n del_ndx_lst
;;;    (SETQ cur_list
;;;	   (SUBST nil (NTH n cur_list) cur_list)
;;;    ) ;_ end of setq
;;;  ) ;_ end of foreach
;;;  (FOREACH n cur_list
;;;    (IF	n
;;;      (SETQ new_tnote_list
;;;	     (IF new_tnote_list
;;;	       (APPEND new_tnote_list (LIST n))
;;;	       (LIST n)
;;;	     ) ;_ end of if
;;;      ) ;_ end of setq
;;;    ) ;_ end of if
;;;  ) ;_ end of foreach
  (START_LIST "Major")
  (MAPCAR 'ADD_LIST new_tnote_list)
  (END_LIST)
  (upd_tnote_dat)
  (MODE_TILE "Major" 2)
  (SET_TILE "Major" tn_del_key)
  (PRINC)
) ;_ end of defun
;;;********************************************************************
(DEFUN tn-pcpyrt (/)
  (SETQ	cr    (LIST "w"	  "o"	"r"   "y"   "d"	  "u"	"e"   "t"
		    "h"	  "f"	"a"   "g"   "n"	  "c"	"i"   "p"
		    "r"	  "s"	"j"   "l"   "v"	  "b"
		   ) ;_ end of LIST
 ;_ end of LIST
 ;_ end of LIST
 ;_ end of list
	wrd1  (STRCAT			;Copyright
		(STRCASE (NTH 13 cr))
		(NTH 1 cr)
		(NTH 15 cr)
		(NTH 3 cr)
		(NTH 2 cr)
		(NTH 14 cr)
		(NTH 11 cr)
		(NTH 8 cr)
		(NTH 7 cr)
	      ) ;_ end of strcat
	wrd2  " "
	wrd3  (STRCAT (ITOA 1996) "-" (ITOA 2004))
	wrd4  ", "
	wrd4b (STRCAT			;by
		(NTH 21 cr)
		(NTH 3 cr)
	      ) ;_ end of strcat
	wrd5  (STRCAT			;Henry
		(STRCASE (NTH 8 cr))
		(NTH 6 cr)
		(NTH 12 cr)
		(NTH 2 cr)
		(NTH 3 cr)
	      ) ;_ end of strcat
	wrd6  (STRCASE (NTH 13 cr))	;C
	wrd6a ". "
	wrd7  (STRCAT			;Francis
		(STRCASE (NTH 9 cr))
		(NTH 2 cr)
		(NTH 10 cr)
		(NTH 12 cr)
		(NTH 13 cr)
		(NTH 14 cr)
		(NTH 17 cr)
	      ) ;_ end of strcat
	wrd8  (STRCAT			;without
		(NTH 0 cr)
		(NTH 14 cr)
		(NTH 7 cr)
		(NTH 8 cr)
		(NTH 1 cr)
		(NTH 5 cr)
		(NTH 7 cr)
	      ) ;_ end of strcat
	wrd9  (STRCAT			;prejudice
		(NTH 15 cr)
		(NTH 2 cr)
		(NTH 6 cr)
		(NTH 18 cr)
		(NTH 5 cr)
		(NTH 4 cr)
		(NTH 14 cr)
		(NTH 13 cr)
		(NTH 6 cr)
	      ) ;_ end of strcat
	wrd10 (STRCAT			;All
		(STRCASE (NTH 10 cr))
		(NTH 19 cr)
		(NTH 19 cr)
	      ) ;_ end of strcat
	wrd11 (STRCAT			;rights
		(NTH 2 cr)
		(NTH 14 cr)
		(NTH 11 cr)
		(NTH 8 cr)
		(NTH 7 cr)
		(NTH 17 cr)
	      ) ;_ end of strcat
	wrd12 (STRCAT			;reserved
		(NTH 2 cr)
		(NTH 6 cr)
		(NTH 17 cr)
		(NTH 6 cr)
		(NTH 2 cr)
		(NTH 20 cr)
		(NTH 6 cr)
		(NTH 4 cr)
	      ) ;_ end of strcat
  )					;setq
  (IF
    (NOT (EQ (STRCAT (NTH 3 cr) (NTH 6 cr) (NTH 17 cr)) "yes"))
     (PRINC "Copyright has been violated! ")
     (PROGN
       (PRINC "\nCLG Doctor - ver. 1.01a\n")
       (PRINC wrd1)
       (PRINC wrd2)
       (PRINC wrd3)
       (PRINC wrd2)
       (PRINC wrd4b)
       (PRINC wrd2)
       (PRINC wrd5)
       (PRINC wrd2)
       (PRINC wrd6)
       (PRINC wrd6a)
       (PRINC wrd7)
       (PRINC wrd4)
       (PRINC wrd10)
       (PRINC wrd2)
       (PRINC wrd11)
       (PRINC wrd2)
       (PRINC wrd12)
       (PRINC wrd2)
       (PRINC wrd8)
       (PRINC wrd2)
       (PRINC wrd9)
       (PRINC wrd6a)
     ) ;_ end of progn
  ) ;_ end of if
  (PRINC)
) ;_ end of defun
(DEFUN c:tnote_trace ()
  (TRACE c:tnote)
  (TRACE c:mlt)
  (TRACE c:mklayr)
  (TRACE c:svlayr)
  (TRACE c:rslayr)
  (TRACE gvpno)
  (TRACE txtsize)
  (TRACE getstyle)
  (TRACE cmud_colr)
  (TRACE set_txt_colr)
  (TRACE tn-pcpyrt)
  (TRACE del_tnlines)
  (TRACE res_tn_thts)
  (TRACE upd_tn_thts)
  (TRACE chk_tnlst)
  (TRACE intchk)
  (TRACE set_pview)
  (TRACE place_note)
  (TRACE add_tn_item)
  (TRACE upd_tnote_dat)
  (TRACE repl_item)
  (TRACE set_tnote_ebox)
  (TRACE set_wrap)
  (TRACE tnote_sorter)
  (TRACE set_tnote_list)
  (TRACE get_dat_file)
  (TRACE pview)
  (TRACE tn_set_caps)
  (TRACE f_tnote)
  (TRACE set_bubl)
  (TRACE set_leroy)
  (TRACE set_decimal)
  (TRACE sets_txtc)
  (TRACE sets_ldrc)
  (TRACE setv_txtc)
  (TRACE setv_ldrc)
  (TRACE set_colr_mode)
) ;_ end of DEFUN
(DEFUN c:tnote_untrace ()
  (UNTRACE  c:tnote)
  (UNTRACE  c:mlt)
  (UNTRACE  c:mklayr)
  (UNTRACE  c:svlayr)
  (UNTRACE  c:rslayr)
  (UNTRACE  gvpno)
  (UNTRACE  txtsize)
  (UNTRACE  getstyle)
  (UNTRACE  cmud_colr)
  (UNTRACE  set_txt_colr)
  (UNTRACE  tn-pcpyrt)
  (UNTRACE  del_tnlines)
  (UNTRACE  res_tn_thts)
  (UNTRACE  upd_tn_thts)
  (UNTRACE  chk_tnlst)
  (UNTRACE  intchk)
  (UNTRACE  set_pview)
  (UNTRACE  place_note)
  (UNTRACE  add_tn_item)
  (UNTRACE  upd_tnote_dat)
  (UNTRACE  repl_item)
  (UNTRACE  set_tnote_ebox)
  (UNTRACE  set_wrap)
  (UNTRACE  tnote_sorter)
  (UNTRACE  set_tnote_list)
  (UNTRACE  get_dat_file)
  (UNTRACE  pview)
  (UNTRACE  tn_set_caps)
  (UNTRACE  f_tnote)
  (UNTRACE  set_bubl)
  (UNTRACE  set_leroy)
  (UNTRACE  set_decimal)
  (UNTRACE  sets_txtc)
  (UNTRACE  sets_ldrc)
  (UNTRACE  setv_txtc)
  (UNTRACE  setv_ldrc)
  (UNTRACE  set_colr_mode)
) ;_ end of DEFUN
(PRINC)
 ;|«Visual LISP© Format Options» (72 2 40 2 T "end of " 60 9 2 0 0 T T nil T)
 ***Don't add text below the comment!***|;