;;;Modify the text width factor of a selection set of text entities.
;;;       The only input required is the desired
;;;       text width factor and selection of the text to modify.  There
;;;       is no need to worry about not selecting non-text entities
;;;       because they will be automatically filtered out of the
;;;       selection set.
;;;
;;;	AUTHOR: HENRY C. FRANCIS
;;;		425 N. ASHE ST.
;;;		SOUTHERN PINES, NC 28387
;;;              
;;;		All rights reserved without prejudice.
;;;	Copyright:	6-7-94
;;;	Edited:		6-18-99
;;;
(DEFUN C:TWID (/ tset tsln cntr tent edtw)
  (SETQ	twf (ureal 1
		   ""
		   "\nText Width Factor "
		   (IF twf
		     twf
		     1.0
		   ) ;_ end of if
	    ) ;_ end of ureal
  )					;
  (PROMPT "\nSelect Text: ")
  (SETQ	tset (SSGET '((-4 . "<or")
		      (0 . "TEXT")
		      (0 . "ATTDEF")
		      (-4 . "<and")
		      (0 . "INSERT")
		      (66 . 1)
		      (-4 . "and>")
		      (-4 . "or>")
		     )
	     ) ;_ end of ssget
  ) ;_ end of setq
  (IF tset
    (PROGN
      (SETQ tsln (SSLENGTH tset))
      (SETQ cntr 0)
    ) ;_ end of progn
  ) ;_ end of if
  (WHILE
    (IF	(AND (< cntr tsln) tset)
      (SETQ tent (ENTGET (SSNAME tset cntr)))
    )					;if
     (PROGN
       (SETQ edtw (ENTGET (CDAR tent)))
       (IF (OR
	     (EQ (CDR (ASSOC 0 edtw)) "TEXT")
	     (EQ (CDR (ASSOC 0 edtw)) "ATTDEF")
	   )				;or
	 (PROGN
	   (SETQ edtw
		  (SUBST (CONS 41 twf)
			 (ASSOC 41 edtw)
			 edtw
		  ) ;_ end of subst
	   ) ;_ end of setq
	   (ENTMOD edtw)
	 ) ;_ end of progn
	 (WHILE	(/= (CDR (ASSOC 0 edtw)) "SEQEND")
	   (COND ((EQ (CDR (ASSOC 0 edtw)) "ATTRIB")
		  (GRDRAW (POLAR (CDR (ASSOC 10 edtw))
				 (* PI 1.25)
				 (CDR (ASSOC 40 edtw))
			  ) ;_ end of polar
			  (POLAR (CDR (ASSOC 10 edtw))
				 (* PI 0.25)
				 (CDR (ASSOC 40 edtw))
			  ) ;_ end of polar
			  -1
			  1
		  ) ;_ end of GRDRAW
		  (GRDRAW (POLAR (CDR (ASSOC 10 edtw))
				 (* PI 1.75)
				 (CDR (ASSOC 40 edtw))
			  ) ;_ end of polar
			  (POLAR (CDR (ASSOC 10 edtw))
				 (* PI 0.75)
				 (CDR (ASSOC 40 edtw))
			  ) ;_ end of polar
			  -1
			  1
		  ) ;_ end of GRDRAW
		  (SETQ	mod_attrq (ukword 1
					  "Yes No"
					  (STRCAT "\nModify attribute, Tag = <"
						  (CDR (ASSOC 2 edtw))
						  ">, Value = <"
						  (CDR (ASSOC 1 edtw))
						  ">?"
					  ) ;_ end of strcat
					  (IF mod_attrq
					    mod_attrq
					    "No"
					  ) ;_ end of if
				  ) ;_ end of ukword
		  ) ;_ end of setq
		  (GRDRAW (POLAR (CDR (ASSOC 10 edtw))
				 (* PI 1.25)
				 (CDR (ASSOC 40 edtw))
			  ) ;_ end of polar
			  (POLAR (CDR (ASSOC 10 edtw))
				 (* PI 0.25)
				 (CDR (ASSOC 40 edtw))
			  ) ;_ end of polar
			  -1
			  1
		  ) ;_ end of GRDRAW
		  (GRDRAW (POLAR (CDR (ASSOC 10 edtw))
				 (* PI 1.75)
				 (CDR (ASSOC 40 edtw))
			  ) ;_ end of polar
			  (POLAR (CDR (ASSOC 10 edtw))
				 (* PI 0.75)
				 (CDR (ASSOC 40 edtw))
			  ) ;_ end of polar
			  -1
			  1
		  ) ;_ end of GRDRAW
		  (IF (EQ mod_attrq "Yes")
		    (PROGN
		      (SETQ edtw
			     (SUBST (CONS 41 twf)
				    (ASSOC 41 edtw)
				    edtw
			     ) ;_ end of subst
		      ) ;_ end of setq
		      (ENTMOD edtw)
		      (ENTUPD (CDAR tent))
		    ) ;_ end of progn
		  ) ;_ end of if
		 )
	   ) ;_ end of COND
	   (SETQ edtw (ENTGET (ENTNEXT (CDR (ASSOC -1 edtw)))))
	 ) ;_ end of WHILE
       ) ;_ end of if
     ) ;_ end of progn
     (SETQ cntr (1+ cntr))
  ) ;_ end of while
)					;DEFUN

;|«Visual LISP© Format Options» (84 2 40 2 T "end of " 60 9 2 0 0 T T nil T)
 ***Don't add text below the comment!***|;